topic conditional run when a data was created on last sunday in SAS Programming

conditional run when a data was created on last sunday

Suzy_Cat — Thu, 24 Sep 2020 23:05:58 GMT

Happy Friday!

i need set up a program automatically run data test1 has been updated last Sunday.

below attached are the code i can not yet make it work. have tried different variations on condition (%if &&CreatedDate_&ds.=intnx('week1.1',today(),0) %then %do;) but issue always lies with intnx('week1.1',today(),0)

Any suggestions?

data test1;
A="this is a test data!";
TodayD=today();
format TodayD date9.;
run;

%macro check_DS_CRDATE(lib,DS);

proc contents data=&lib..&ds. noprint out=DS_Date (keep= MEMNAME MEMLABEL CRDATE MODATE); run;

proc sql noprint;
select distinct CRDATE, datepart(CRDATE)
into : CreatedTime_&ds., :CreatedDate_&ds.
from DS_Date;
%put data &ds. was created at =&&CreatedTime_&ds.;
%put data &ds. was created on =&&CreatedDate_&ds.;

%if &&CreatedDate_&ds.=intnx('week1.1',today(),0) %then %do;
data test_successful;
ref=today();
A="Great effort!";
LastSunday=intnx('week1.1',ref,0);
run;
%end;

run;

%mend check_DS_CRDATE;

%check_DS_CRDATE(work, test1);

Re: conditional run when a data was created on last sunday

Suzy_Cat — Thu, 24 Sep 2020 23:14:17 GMT

while tested on intnx('week1.1',today(),0), it returned a numeric value as LastSunday.

data test;
LastSunday=intnx('week1.1',today(),0);
format _all_ date9.;
put (_all_)(=/);
run;

Re: conditional run when a data was created on last sunday

novinosrin — Thu, 24 Sep 2020 23:28:15 GMT

%if &&CreatedDate_&ds.=%sysfunc(intnx(week1.1,%sysfunc(today()),0)) %then %do;

Syntax should be :

%sysfunc(intnx(week1.1,%sysfunc(today()),0))

Test:

%let  LastSunday= %sysfunc(intnx(week1.1,%sysfunc(today()),0),date9.);

%put LastSunday=&LastSunday;

Re: conditional run when a data was created on last sunday

CurtisMackWSIPP — Thu, 24 Sep 2020 23:20:20 GMT

Your main problem was trying to call INTNX in open code. You must wrap in in $SYSFUNC for it to work. Same is true of the TODAY functions. Give this a try:


data test1;
A="this is a test data!";
TodayD=today();
format TodayD date9.;
run;


%macro check_DS_CRDATE(lib,DS);

proc contents data=&lib..&ds. noprint out=DS_Date (keep= MEMNAME MEMLABEL CRDATE MODATE); run;

proc sql noprint;
  select distinct CRDATE, datepart(CRDATE)
  into :CreatedTime_&ds., :CreatedDate_&ds.
  from DS_Date;
quit;
%put data &ds. was created at =&&CreatedTime_&ds.;
%put data &ds. was created on =&&CreatedDate_&ds.;
%let tday = %sysfunc(intnx(%str(week1.1),%sysfunc(today()),0));
%put tday = &tday;

%if &&CreatedDate_&ds.=%sysfunc(intnx(%str(week1.1),%sysfunc(today()),0)) %then %do;
  data test_successful;
    ref=today();
    A="Great effort!";
    LastSunday=intnx('week1.1',ref,0);
  quit;
%end;

%mend check_DS_CRDATE;

%check_DS_CRDATE(work, test1);

Re: conditional run when a data was created on last sunday

Suzy_Cat — Thu, 24 Sep 2020 23:32:05 GMT

Super... it worked like a gem!

had thought so and tried %sysfun c(intnx(week1.1,today(),0),date9.) but not on today()

Re: conditional run when a data was created on last sunday

Suzy_Cat — Thu, 24 Sep 2020 23:35:07 GMT

Thank you guys for the quick and professional fix 🙂

really appreciated !