topic Re: If condition with macro variables in SAS Programming

If condition with macro variables

Aman4SAS — Thu, 24 Sep 2020 15:20:19 GMT

Hi All, I need to compare 2 macro variables but i am getting always condition false while condition is true as per my data. Please help
Code:
DATA X;
INPUT X$ Y$;
DATALINES;
X 2
;
RUN;
DATA Y;
X="2";
RUN;
%MACRO TEST();
%GLOBAL FLAG;
PROC SQL;
SELECT DISTINCT X,Y INTO :A,:B FROM X;
QUIT;
%LET A=%LEFT(%TRIM(&A));
%LET B=%LEFT(%TRIM(&B));
%IF &A. = %BQUOTE('&B.') %THEN
%LET FLAG=Y;
%ELSE
%LET FLAG=N;
%MEND;
DATA NEW;
SET Y;
CALL EXECUTE('%TEST();');
FLAG=SYMGET('FLAG');
RUN;

Please help

Re: If condition with macro variables

CurtisMackWSIPP — Thu, 24 Sep 2020 15:38:06 GMT

This is not working because the call execute executes after the data step is complete, so FLAG isn't set until after the data step is done.

Why are you calling the macro using call execute? Is this just an example from a larger solution?

Re: If condition with macro variables

ballardw — Thu, 24 Sep 2020 15:38:01 GMT

Show some example values from both of these "variables" and why you think they are equal.

Or set

Options mprint mlogic symbolgen before running your macro.

The %Left (%Trim( &A.)) is not going to remove, reduce or effect the spacing between different bits of &A. The whole string gets shifted left and the only thing "trimmed" is what comes after the last bit.

Example:

%let A =   Some      words   with differing spaces     betweeeen    ;
%let A = %trim(%left(&A.));

%put &A.;

You might need to Strip the variables (equivalent to Left(trim())) and specify Separated by ' ' to force on blank between the values of the variables. However if some values of the A or B data set variables have differing numbers of blanks embedded in them you really need to provide example data and what you expect.

Re: If condition with macro variables

Aman4SAS — Thu, 24 Sep 2020 15:40:07 GMT

Its just an example, i need to use it with big data by checking multiple conditions and need to call macro recursivly untill i reach my end node
Is there any solution?

Re: If condition with macro variables

CurtisMackWSIPP — Thu, 24 Sep 2020 15:42:41 GMT

Well this version works. How does it not work in your situation?

DATA X;
INPUT X$ Y$;
DATALINES;
X 2
;
RUN;
DATA Y;
X="2";
RUN;
%MACRO TEST();
  %GLOBAL FLAG;
  PROC SQL;
  SELECT DISTINCT X,Y INTO :A,:B FROM X;
  QUIT;
  %LET A=%LEFT(%TRIM(&A));
  %LET B=%LEFT(%TRIM(&B));
  %IF &A. = %BQUOTE('&B.') %THEN
  %LET FLAG=Y;
  %ELSE
  %LET FLAG=N;
%MEND;
%TEST();
DATA NEW;
SET Y;
FLAG="&FLAG";
RUN;

Re: If condition with macro variables

Aman4SAS — Thu, 24 Sep 2020 15:43:26 GMT

As my example i have only one character to check. LIKE 1 2 3 4 5 A B C D These flags which i need to check , provided is just an example. But going through always false and Flag is being assign as N

Re: If condition with macro variables

CurtisMackWSIPP — Thu, 24 Sep 2020 15:49:13 GMT

Your example is confusing me. You are trying to call that macro while accessing data set Y, but you are not actually referencing any values in that table.

I suggest backing up and telling us what you are trying to do, as I don't think this approach will work.

Re: If condition with macro variables

Aman4SAS — Thu, 24 Sep 2020 15:50:01 GMT

Not able to understand, u call macro outside of datastep it will run only 1 time, and u r getting Flag value Y?

Re: If condition with macro variables

CurtisMackWSIPP — Thu, 24 Sep 2020 15:51:57 GMT

The value is always false because you are always comparing "X" to "2" from dataset X. You aren't accessing anything from dataset Y.

Re: If condition with macro variables

CurtisMackWSIPP — Thu, 24 Sep 2020 15:52:55 GMT

I suspect you could solve this with a custom made format.

Re: If condition with macro variables

Aman4SAS — Thu, 24 Sep 2020 15:55:05 GMT

Apology,
I have a table with conditions
I have created macrovariables for conditions where macro variable A is column name and Macro variable b is value. While calling inside datastep condition need to check with row. And want to all flag. Its only step. If condition get true i will pick another variable as reference to pick another condition as macro variable and will check again untill last node.

My problem is here when macro variable are resolving correct value as per data why my condition is not getting true

Re: If condition with macro variables

Aman4SAS — Thu, 24 Sep 2020 16:02:28 GMT

Same is working , diff is not proc sql to create macro varible;
Code:
%GLOBAL FLAG;
%MACRO TEST();
%LET VAR=NAME;
%LET SEX=M;
%LET COND= =;
%IF &VAR &COND %BQUOTE('&SEX') %THEN %LET FLAG=Y;
%ELSE %LET FLAG=N;
%MEND;
DATA NEW;
SET SASHELP.CLASS;
CALL EXECUTE('TEST();');
FLAG=CALL SYMGET('FLAG');
RUN;

Its working fine.

Plz help

Re: If condition with macro variables

PaigeMiller — Thu, 24 Sep 2020 16:30:39 GMT

You can't refer to DATA set variables like NAME using a macro variable &VAR inside a macro. When you use &VAR to refer to a data set variable, you must use it inside a SAS data step. If you want to compare a data set variable to some other value, it must be done in a DATA step, using a data step IF statement and not a macro %IF statement, which only compares macro variables to a value.

So nothing you are trying to do with this macro will work.

You could, however, create code like this, that works inside a DATA step

%LET VAR=NAME;
%LET SEX=M;
%LET COND= =;

data want;
    set sashelp.class;
    if &var &cond "&sex" then flag='Y';
run;

Of course, your logic still fails, but the code produces no errors. Why does the code work now? Because &VAR is replaced with NAME and &COND is replaced by = and &SEX is replaced by M, yielding the line of code if name="M" then flag='Y'; inside a DATA step, which is indeed valid SAS code.

The logic fails because there are no observations in SASHELP.CLASS for which the variable NAME is equal to the value of "M". But I leave that up to you to fix.

Re: If condition with macro variables

CurtisMackWSIPP — Thu, 24 Sep 2020 16:28:03 GMT

Remember, macro write code, they cannot read the values in a data step.

I think this is what you want.

DATA X;
INPUT X$ Y$;
DATALINES;
X 2
;
RUN;
DATA Y;
X="2"; 
RUN;
%MACRO TEST();
  %let dsid = %sysfunc(open(work.X));
  %do %while(%sysfunc(fetch(&dsid)) = 0);
    %let varname = %sysfunc(getvarc(&dsid,1));
    %let varval = %sysfunc(getvarc(&dsid,2)); 
    if &varname = "&varval" then FLAG = 'Y';
    else FLAG = 'N'; 
  %end;
  %let rc   = %sysfunc(close(&dsid));
%MEND;
options mprint;
DATA NEW;
SET Y;
%TEST();
RUN;

Notice the MPRINT option. This will show you in the log the code that got created.

Re: If condition with macro variables

CurtisMackWSIPP — Thu, 24 Sep 2020 16:41:06 GMT

Here is a call execute version. Remember all it does is write code as well.

data _null_;
  set x end=finished;
  if _n_ = 1 then do;
    CALL EXECUTE('DATA NEW;');
    CALL EXECUTE('SET Y;');
  end;
  CALL EXECUTE('if ' || X || ' = "' || strip(Y) || '" then FLAG="Y";');
  CALL EXECUTE('else FLAG="N";');
  if finished then do;
    CALL EXECUTE('run;');
  end;
run;

Re: If condition with macro variables

PaigeMiller — Thu, 24 Sep 2020 17:09:51 GMT

Adding to my reply above

Here's a macro that does what you want

%macro subset(dsn=,var=,cond=,value=);
data want;
    set &dsn;
    if &var &cond "&value" then flag='Y';
run;
%mend;

/* Example: */
%subset(dsn=sashelp.class,var=name,cond=%str(=),value=Jane)

/* Example 2: */
%subset(dsn=sashelp.class,var=name,cond=%str(=:),value=J)

Works when &var references a data set character variable. Note that the comparison of the data step variable is done in a data step IF statement and not in a macro %IF statement, which cannot compare data step variables to a value.

Re: If condition with macro variables

Aman4SAS — Thu, 24 Sep 2020 18:05:46 GMT

Thanks a lot, it works, but i need to create this x table again n again like i have 10 conditions on diff diff variables i need to check every variable with conditions for each row. By this i wont be able to create x dynamicly. I need to pick 1st row for 1st condition , 2nd row for 2nd condition, i need to call same macro recursively. Thanks again

Re: If condition with macro variables

PaigeMiller — Thu, 24 Sep 2020 18:15:32 GMT

@Aman4SAS wrote:
By this i wont be able to create x dynamicly. I need to pick 1st row for 1st condition , 2nd row for 2nd condition, i need to call same macro recursively.

Show us what you mean, "pick 1st row..."

You should be able to call the macro from within a data set using the code from @CurtisMackWSIPP

Re: If condition with macro variables

CurtisMackWSIPP — Thu, 24 Sep 2020 18:19:12 GMT

You can just add rows to the X table and it should work.

Re: If condition with macro variables

CurtisMackWSIPP — Thu, 24 Sep 2020 18:28:47 GMT

You can't call a macro for every row in a data step. The macros write code that is then executed. Look at this call execute that will sets FLAG to equal which variable matched the values in the X. Pay attention to the log. It will show you the code that is actually generated.

DATA X;
INPUT X$ Y$;
DATALINES;
X 2
Y 4 
;
RUN;
DATA Y;
X="2";Y="0"; output;
X="0";Y="4"; output;
X="5";Y="3"; output;
RUN;
data _null_;
  set x end=finished;
  if _n_ = 1 then do;
    CALL EXECUTE('DATA NEW;');
    CALL EXECUTE('SET Y;');
    CALL EXECUTE('if 0 = 1 then FLAG="";');
  end;
  CALL EXECUTE('else if ' || X || ' = "' || strip(Y) || '" then FLAG="' || strip(X) || '";');
  if finished then do;
    CALL EXECUTE('else FLAG="N";');
    CALL EXECUTE('run;');
  end;
run;