topic Re: Extract the characters before the second "-" in the value in SAS Programming

Extract the characters before the second "-" in the value

yichentian226 — Wed, 23 Sep 2020 18:20:58 GMT

Hi,

I am trying to extract the characters before the second "-" in the value (name is pagepath). Any ideas or thoughts are appreciated!

Re: Extract the characters before the second "-" in the value

Reeza — Wed, 23 Sep 2020 19:06:10 GMT

SCAN() or a regex.

Re: Extract the characters before the second "-" in the value

yichentian226 — Wed, 23 Sep 2020 19:09:02 GMT

Thanks for the reply, I used scan function and I could extract characters before the first "-", but I'm not sure how to extract characters before the second "-". Here's an example, abc-def-ghi, I want to get result as "abc-def".

Re: Extract the characters before the second "-" in the value

Reeza — Wed, 23 Sep 2020 19:12:33 GMT

Show your code. What did you put as the second and third parameters?

SCAN(string, count <, character-list <, modifier>>)

Re: Extract the characters before the second "-" in the value

mklangley — Wed, 23 Sep 2020 19:36:56 GMT

@yichentian226 Here's one way to do it:

data have;
    input pagepath $25.;
    datalines;
    abc-def-ghi-jkl
    testing-it-again
    ;
run;

data want (drop=p i);
    set have;
    p = 0;
    do i=1 to 2 until(p=0); 
        p = find(pagepath, '-', p+1);
    end;
    if p ne 0 then str_before_2nd_hyphen = substr(pagepath, 1, p-1);
run;

Reference: https://blogs.sas.com/content/sgf/2019/06/26/finding-n-th-instance-of-a-substring-within-a-string/

Re: Extract the characters before the second "-" in the value

jimbarbour — Wed, 23 Sep 2020 19:30:22 GMT

Program:

data Have;
	DROP	Second_Dash_Position;
	DROP	String_Length;
	LENGTH	With_Dashes	$35;
	INPUT	With_Dashes	$;
	Second_Dash_Position	=	FIND(With_Dashes, '-', (INDEX(With_Dashes, '-') + 1));
	String_Length			=	LENGTH(With_Dashes)	-	(LENGTH(With_Dashes)	-	Second_Dash_Position) - 1;
	IF	Second_Dash_Position	THEN
		Before_the_Dashes	=	SUBSTR(With_Dashes, 1, String_Length);
datalines;
happy-go-lucky
fleet-of-foot
down-in-the-mouth
woe-begone
fine-and-dandy
In-like-Flynn
The-more-the-merrier
;
RUN;

Results:

Jim

Re: Extract the characters before the second "-" in the value

Astounding — Wed, 23 Sep 2020 20:10:56 GMT

This should work:

want = catx('-', scan(string, 1, '-'), scan(string, 2, '-') );

Re: Extract the characters before the second "-" in the value

yichentian226 — Wed, 23 Sep 2020 21:26:55 GMT

I really like your way of solving it! Thanks it's great 🙂

Re: Extract the characters before the second "-" in the value

yichentian226 — Wed, 23 Sep 2020 21:28:08 GMT

Thanks it's great! Very helpful

Re: Extract the characters before the second "-" in the value

yichentian226 — Wed, 23 Sep 2020 21:28:48 GMT

Thanks very much it worked!