topic Re: Matching against multiple keywords in SAS Programming

Matching against multiple keywords

a_khedekar — Wed, 16 Sep 2020 22:00:13 GMT

data custnm;
infile datalines;
input name $50.;
datalines;
ABC AMERICAN REALTY
ABC MARKETING
ABC YOGA
;
run;

data kwds;
infile datalines;
input keyword $15.;
datalines;
ABC
AMERICAN
;
run;

I want to match flag to return 2 since two keyword matched for first record and return 1 for one keyword match.

Let me know if anyone has any solutions around it.

Re: Matching against multiple keywords

ballardw — Wed, 16 Sep 2020 22:21:02 GMT

How many total keywords do you have in your list? There are some approaches that may work for short lists that don't work for longer ones.

Should embedded strings "match"? Example: Does keyword "ABC" match value "ABCDE"?

Are your matches case sensitive? You show everything in upper case but what if you have a value of "Abc". Should that match "ABC" or not.

What if the same string appears more than once in the value? Would a value of "ABC MARKETING ABC PRODUCTS" have ABC counted as 1 or 2?

Re: Matching against multiple keywords

CurtisMackWSIPP — Wed, 16 Sep 2020 22:49:11 GMT

There is a hash approach that would be best, but this is a simple to understand example.

proc sql;
  create table matches as 
  select name,count(*) as keywords
  from custnm, kwds
  where findw(name,strip(keyword)) > 0
  group by name;
quit;

Re: Matching against multiple keywords

CurtisMackWSIPP — Wed, 16 Sep 2020 23:01:10 GMT

Here is a hash solution. Harder to code, but should scale much better.

data matches(keep=name keywords);
  if _n_ = 1 then do;
	 declare hash kwds(dataset:"kwds");
	 kwds.defineKey("keyword");
	 kwds.defineDone();
  end;
  set custnm;
  keywords = 0;
  delims = ' ';     
  numWords = countw(name, delims);  /* for each line of text, how many words? */
  do i = 1 to numWords;            /* split text into words */
     keyword = scan(name, i, delims);
     if kwds.check() eq 0 then keywords = keywords + 1;
  end;
run;