topic Re: Iterate over a list of numeric value in SAS in SAS Programming

Iterate over a list of numeric value in SAS

mazouz — Thu, 03 Sep 2020 14:59:38 GMT

Hello,

I want to creat a loop that that iterate over a list of numeric value like this :

LIST => [1, 3, 5, 7, 20,100,2000]
   
%DO i  %IN LIST;

Re: Iterate over a list of numeric value in SAS

PaigeMiller — Thu, 03 Sep 2020 15:03:03 GMT

In a DATA step, this is how to do it.

data nothing;
	do i= 1, 3, 5, 7, 20,100,2000;
	    output;
	end;
run;

Re: Iterate over a list of numeric value in SAS

Tom — Thu, 03 Sep 2020 15:10:06 GMT

Do you need to do this in real SAS code? Your syntax looks like IML are you using IML? The data step also can use a comma separated list of values in a DO statement.

do i= 1, 3, 5, 7, 20,100,2000;

Some of them can be ranges if you want.

do i= 1 to 7 by 2, 20,100,2000;

Or are you trying to use the macro processor to generate something? The macro processor does not have any syntax for that. Just make a list and iterate over an index into the list.

%let list = 1 3 5 7 20 100 2000;
%do index = 1 %to %sysfunc(countw(&list,%str( )));
  %let I =%scan(&list,&index,%str( ));
....
%end;

Re: Iterate over a list of numeric value in SAS

mazouz — Thu, 03 Sep 2020 15:22:46 GMT

%let list = 1 3 5 7 20 100 2000;

%MACRO WANT(variable,table);
%do index = 1 %to %sysfunc(countw(&list,%str( )));
%let I =%scan(&list,&index,%str( ));
%FUNCTION(&variable,&table,I);
%END;
%MEND;

%WANT(VAR1,HAVE);

I want to iterate function, I try this but don't work.

Re: Iterate over a list of numeric value in SAS

Tom — Thu, 03 Sep 2020 15:26:29 GMT

Define how it doesn't work. I notice that you are setting a value to I but you never use it. Did you mean to use &I instead of I in the call to %FUNCTION() macro?

Re: Iterate over a list of numeric value in SAS

mazouz — Thu, 03 Sep 2020 15:30:27 GMT

Yes

%FUNCTION is a macro that i want to iterat for i in list

Re: Iterate over a list of numeric value in SAS

PaigeMiller — Thu, 03 Sep 2020 15:34:19 GMT

I don't know what %FUNCTION is, I don't have that macro.

However, the rest of your code works fine if I comment out %FUNCTION

%let list = 1 3 5 7 20 100 2000;

%MACRO WANT(variable,table);
%do index = 1 %to %sysfunc(countw(&list,%str( )));
%let I =%scan(&list,&index,%str( ));
/*%FUNCTION(&variable,&table,I);*/
%put &=i;
%END;
%MEND;

%WANT(VAR1,HAVE)

Perhaps you should use

%FUNCTION(&variable,&table,&I);

Important concept for your future reference: saying something "don't work" and providing no other information is never helpful to us and is never helpful to you in resolving these issues.

Re: Iterate over a list of numeric value in SAS

Kurt_Bremser — Thu, 03 Sep 2020 15:35:36 GMT

Here

%FUNCTION(&variable,&table,I);

you feed the one-character text I to your macro. If you wanted it to get the value stored in the macro variable I, you need to address it correctly:

%FUNCTION(&variable,&table,&I);

Re: Iterate over a list of numeric value in SAS

Tom — Thu, 03 Sep 2020 15:36:28 GMT

@mazouz wrote:

Yes

%FUNCTION is a macro that i want to iterat for i in list

Does that macro want a number as the value of the third parameter or a macro variable name? Currently you are just giving it the letter I.

%function(...,i)

If you want to give it the values like 1 and 2000 instead then use &I in the call to the macro.

%function(....,&i)

Re: Iterate over a list of numeric value in SAS

mazouz — Thu, 03 Sep 2020 15:39:55 GMT

thank you 😉

Re: Iterate over a list of numeric value in SAS

mazouz — Thu, 03 Sep 2020 16:18:06 GMT

this time i want to iterate over a list of char variable. can I use same code?

Re: Iterate over a list of numeric value in SAS

PaigeMiller — Thu, 03 Sep 2020 16:19:41 GMT

@mazouz wrote:

this time i want to iterate over a list of char variable. can I use same code?

Depending on how your macro %FUNCTION is written, the answer is either YES or NO.

But the macro loop that we are working with doesn't care if the values are numeric or character.