topic Re: Convert YYYY-MM character value to numeric in SAS Programming

Convert YYYY-MM character value to numeric

David_Billa — Wed, 19 Aug 2020 08:24:55 GMT

I'm trying to convert YYYY-MM character value to numeric with the format yymmd7. but it's not working as it producing null values. Desired output is same as source dataset but with numeric data type. Any guidance?

data have;
    input  Start_Mo $ End_Mo $;
    datalines;
    2017-03    2017-09
    2016-03    2018-09
    ;
run;

data want;
    set have;
    Start_mo_num=input(Start_Mo,best32.);
    End_mo_num=input(End_Mo,best32.);
    format start_mo_num End_mo_num yymmd7.; 
run;

Re: Convert YYYY-MM character value to numeric

Shmuel — Wed, 19 Aug 2020 08:41:14 GMT

You need to supply a day in order to convert the input into sas date, as in next example:

data a;
 dt = '2017-08';
 date = input(cats(dt,'-01'),yymmdd10.);
 format date yymmd7.;
run;

chaeck dataset a (the result of above code) and adapt your code.

Re: Convert YYYY-MM character value to numeric

David_Billa — Wed, 19 Aug 2020 08:49:05 GMT

Thanks. Any other ways to achieve the excepted results?

Re: Convert YYYY-MM character value to numeric

Kurt_Bremser — Wed, 19 Aug 2020 09:51:10 GMT

data test;
in = "2020-08";
out = input(compress(in,'-'),yymmn6.);
run;

Re: Convert YYYY-MM character value to numeric

PaigeMiller — Wed, 19 Aug 2020 10:58:54 GMT

@David_Billa wrote:
Thanks. Any other ways to achieve the excepted results?

Why is the code from @Shmuel not acceptable? It clearly works.

Re: Convert YYYY-MM character value to numeric

ballardw — Wed, 19 Aug 2020 11:45:01 GMT

@David_Billa wrote:
Thanks. Any other ways to achieve the excepted results?

data have;
    input  Start_Mo $ End_Mo $;
    startdate = input(start_mo,anydtdte.);
    enddate  = input(end_mo, anydtdte.);
    format startdate enddate date9.;
    datalines;
    2017-03    2017-09
    2016-03    2018-09
    ;
run;