topic Re: correction of a wrong date in SAS Programming

correction of a wrong date

MarcTC — Mon, 18 Apr 2011 22:06:20 GMT

Is there any convenient way to correct a wrong date entered by users? For example, if a user enters "31apr2011"d, it will be corrected to "30apr2011"d by the program.

data a;
a="31apr2011"d; /* a_corrected="30apr2011"d */
b="30feb2011"d; /* b_corrected="28feb2011"d */
run;

Re: correction of a wrong date

sbb — Mon, 18 Apr 2011 22:46:04 GMT

Using a DATA step, you would need to use the INPUT function to test the data -- SAS will return a MISSING value if invalid, then set a DO/END loop decrementing by one and again testing the value using INPUT.

For consideration, the INPUT example below shows how to tell SAS to suppress an invalid-data condition from the SASLOG:

test_date = INPUT(,?? DATE9.);

Scott Barry
SBBWorks, Inc.

Re: correction of a wrong date

ArtC — Wed, 20 Apr 2011 03:39:13 GMT

If, as your sample suggests, you are only worried about the last day of the month, the following uses Scott's suggestion to create a new date value.
[pre]
data a;
a="31apr2011"; output;
a="30feb2011"; output;
a="15sep2011"; output;
run;

data last;
set a;
date = INPUT(a,?? DATE9.);
if date= . then do;
substr(a,1,2)='01';
date=intnx('month',input(a,date9.),0,'e');
end;
format date date9.;
run;
proc print data=last;
run;
[/pre]

Clearly there are other date traps that may concern you.

Re: correction of a wrong date

PrasadYadla — Mon, 17 Aug 2020 04:10:05 GMT

Hi,

What if the date column has missing values from before and few dates have the wrong day (31& 32) .

Thanks,

Re: correction of a wrong date

andreas_lds — Mon, 17 Aug 2020 05:04:36 GMT

@PrasadYadla wrote:

Hi,

What if the date column has missing values from before and few dates have the wrong day (31& 32) .

Thanks,

Enclosing the correcting code with an appropriate if-statement should help:

data a;
   a="31apr2011";
   output;
   a="30feb2011";
   output;
   a = " ";
   output;
   a="15sep2011";
   output;
run;

data last;
   set a;

   if not missing(a) then
      do;
         date=INPUT(a, ?? DATE9.);

         if date=. then
            do;
               substr(a, 1, 2)='01';
               date=intnx('month', input(a, date9.), 0, 'e');
            end;
      end;
   format date date9.;
run;

Re: correction of a wrong date

PrasadYadla — Tue, 18 Aug 2020 05:21:05 GMT

Thank you for your reply