SAS filename of output

SaschaD — Wed, 12 Aug 2020 14:45:47 GMT

Hi,

I want to add to the filename the date of today. I tried the code below but it does'nt work.

How can I use my variable pathname in the filename syntax?

data _NULL_;
	StringA = '/project/XXXXX/out/XX_EXPORT_';
	StringM = %sysfunc(today(), YYMMYYN6.);
	StringE = '.csv';
	%LET pathname = cats(StringA, StringM, StringE);
	put pathname;
run;

filename OUTPUT &pathname encoding='utf-8';
proc export data=XXXXXX.XX_NG outfile=OUTPUT dbms=csv;
run;

Thanks,

Sascha

Re: SAS filename of output

Kurt_Bremser — Wed, 12 Aug 2020 15:02:36 GMT

Macro timing mistake. The %LET is dealt with while the data step is compiled, not while it executes.

Use the proper data step function for setting a macro variable:

data _NULL_;
	StringA = '/project/XXXXX/out/XX_EXPORT_';
	StringM = put(today(),YYMMYYN6.);
	StringE = '.csv';
	call symputx('pathname',cats(StringA, StringM, StringE));
run;

But you can do this in one %LET:

%let pathname =/project/XXXXX/out/XX_EXPORT_%sysfunc(today(),YYMMYYN6.).csv;

And since the macro variable &pathname does not contain quotes, add them when it is used:

filename OUTPUT "&pathname" encoding='utf-8';

topic Re: SAS filename of output in SAS Programming

SAS filename of output

Re: SAS filename of output