Filling PROC REPORT Analysis Variable with 0%

tburus — Tue, 11 Aug 2020 03:29:02 GMT

I am running PROC REPORT to compute sample counts and percent of total on a cross-tabulation of variables. In parts of the cross-tab I have no representatives for the variables involved. Initially this just printed as a missing value, but I utilized OPTIONS MISSING=0 to fill with 0's. However, since one of the associated columns calculates a percentage, I would rather that it say 0%. I'm not sure how to make this work.

Code:

proc report data=mfb_ly nowd split="*"
		style(report)=[frame=hsides rules=none]
		style(header)=[background=white color=&rgreen. borderbottomcolor=black]
		style(lines)=[background=white];
	where(not missing(mech));
	options missing=0;
	column mech type,(nationalweight nationalweight=pct) ('Overall' nationalweight=tot nationalweight=totpct ) ;
	define mech / group 'Activity' center order=freq descending style(column)=[cellwidth=2.5in just=l] style(header)=[just=l];
	define type / across '';
	define nationalweight / analysis SUM 'n' format=comma8.0 &cl.;
	define pct / analysis PCTSUM format=percent8.1 '%' style(column)=[cellwidth=0.75in just=c];
	define tot / analysis sum 'n' format=comma8.0 &cl.;
	define totpct / analysis pctsum '%' format=percent8.1 order=freq style(column)=[cellwidth=0.75in just=c];
	rbreak after /summarize style(summary)={font_weight=bold};
	compute mech;
    	if _break_ = '_RBREAK_' then mech = 'Total';
	endcomp;
run;

Output:

Re: Filling PROC REPORT Analysis Variable with 0%

ChrisNZ — Tue, 11 Aug 2020 04:46:13 GMT

Maybe create a new format?

proc format;
  value pct low-high=[percent8.1]  .='0%';

Re: Filling PROC REPORT Analysis Variable with 0%

tburus — Tue, 11 Aug 2020 06:14:16 GMT

That did the trick. Thanks. Would have loved to see a solution that was specific to the PROC and didn't require creating a new coded item, but I couldn't find one (if one even exists).

Re: Filling PROC REPORT Analysis Variable with 0%

ChrisNZ — Tue, 11 Aug 2020 08:34:53 GMT

> Would have loved to see a solution that was specific to the PROC

You might be able to compute something. I like formats 🙂

topic Re: Filling PROC REPORT Analysis Variable with 0% in SAS Programming

Filling PROC REPORT Analysis Variable with 0%

Re: Filling PROC REPORT Analysis Variable with 0%

Re: Filling PROC REPORT Analysis Variable with 0%

Re: Filling PROC REPORT Analysis Variable with 0%