topic Store Date in Variable in SAS Programming

Store Date in Variable

SaschaD — Tue, 11 Aug 2020 06:55:04 GMT

Hello,

I need to store the date in a variable which I want use in other case later.

Below you will find my code. The output of variblae StartDate_OUT is "StartDate=."

If I try to write %LET StartDate_OUT = date(); I get an syntax error.

Where is my mistake?

data _NULL_;
	format StartDate mmddyy10.;
	StartDate = date();
	%LET StartDate_OUT = StartDate=; 
run;

data _NULL_;
	PUT &StartDate_OUT;
run;

Thanks,

Sascha

Re: Store Date in Variable

Shmuel — Tue, 11 Aug 2020 07:49:43 GMT

Replace line

%LET StartDate_OUT = StartDate=;

by:

call symput('StartDate_Out', startdate);

and instead:

data _NULL_;
	PUT &StartDate_OUT;
run;

you can check the value of the macro variable by:

%put StartDate_Out = &StartDate_OUT;

Check the log; The number displayed is the sas value of the date, i.e. the days past since 01JAN1060. In a datastep, use format to display this number in a required format.

Re: Store Date in Variable

Norman21 — Tue, 11 Aug 2020 07:42:54 GMT

startydate?

Re: Store Date in Variable

Shmuel — Tue, 11 Aug 2020 07:51:01 GMT

Sorry for the typo. Post was edited.

Re: Store Date in Variable

andreas_lds — Tue, 11 Aug 2020 08:16:01 GMT

Storing formatted dates in macro-variables is not recommended if you plan to use the variable in comparisons with dataset-variables, because even if the same format is applied to the dataset-variable, the value is still a number.

%global StartDate;
%let StartDate = %sysfunc(today());
%put &=StartDate;

Re: Store Date in Variable

s_lassen — Tue, 11 Aug 2020 10:08:11 GMT

I assume that what you want is to get today's date into the StartDate_OUT macro variable, in the format MMDDYY10.

That is simply accomplished with %SYSFUNC:

%let StartDate_OUT=%sysfunc(today(),mmddyy10.);

Re: Store Date in Variable

Kurt_Bremser — Tue, 11 Aug 2020 10:30:19 GMT

Your code does not result in a syntax ERROR:

 73         data _NULL_;
 74           format StartDate mmddyy10.;
 75           StartDate = date();
 76           %LET StartDate_OUT = StartDate=;
 77         run;
 
 NOTE:  Verwendet wurde: DATA statement - (Gesamtverarbeitungszeit):
       real time           0.00 seconds
       cpu time            0.00 seconds
       
 
 78         
 79         data _NULL_;
 80           PUT &StartDate_OUT;
 81         run;
 
 NOTE: Variable StartDate is uninitialized.
 StartDate=.
 NOTE:  Verwendet wurde: DATA statement - (Gesamtverarbeitungszeit):
       real time           0.00 seconds
       cpu time            0.00 seconds

But you get a NOTE. Will come to that later.

Your first data step:

data _NULL_;
  format StartDate mmddyy10.;
  StartDate = date();
  %LET StartDate_OUT = StartDate=; 
run;

is equivalent to this:

%LET StartDate_OUT = StartDate=;

data _NULL_;
  format StartDate mmddyy10.;
  StartDate = date();
run;

because the macro processor resolves macro statements when they are encountered in the code, before the data step compiler kicks in, compiles the data step code, and runs it.

So you now have assigned this text to the macro variable:

StartDate=

When the macro processor finds this macro variable in the next data step:

data _NULL_;
  PUT &StartDate_OUT;
run;

it replaces the macro variable with the text stored in it, so you get

data _NULL_;
  PUT StartDate=;
run;

which is valid data step syntax, but references a data step variable (startdate) that does not yet exist, so it is created with a missing value, causing the "uninitialized" NOTE.

Keep in mind:

the macro processor is a text replacement engine used to make writing code easier
macro triggers are resolved immediately
macro statements do not have access to data step variables

Re: Store Date in Variable

Kurt_Bremser — Tue, 11 Aug 2020 10:37:24 GMT

Also see Maxim 28. Values stored in macro variables for later use in code rarely need a format. Formatting is only needed if the macro variable in question is used for human-readable display (e-g. in the text of a TITLE statement). In all other cases, the raw values are easier to use when referencing the macro variable.