topic Re: Sign % in text of macro variable in SAS Programming

Sign % in text of macro variable

SASdevAnneMarie — Tue, 04 Aug 2020 11:52:18 GMT

Hello,

I'm trying to resolve the macrovariable &PROFILE that has a text: "ne devra représenter plus de 20 %du profil de gestion".

I get the Warning message: WARNING: Apparent invocation of macro DU not resolved.

Do you know please how to avoid this message?

Thank you very much!

Best regards,

Marie

Re: Sign % in text of macro variable

PeterClemmensen — Tue, 04 Aug 2020 12:03:44 GMT

Use a proper macro quoting function

data _null_;
   call symputx('profile', 'ne devra représenter plus de 20 %du profil de gestion');
run;

%put %superq(profile);

Re: Sign % in text of macro variable

yabwon — Tue, 04 Aug 2020 12:03:56 GMT

try %superq()

data _null_;
  call symputX('PROFILE', 'ne devra représenter plus de 20 %du profil de gestion', "G");
run;

%put %superq(PROFILE);

Re: Sign % in text of macro variable

yabwon — Tue, 04 Aug 2020 12:04:55 GMT

haha! We have almost exactly the same answers 🙂 🙂

B-)

Re: Sign % in text of macro variable

SASdevAnneMarie — Tue, 04 Aug 2020 12:29:55 GMT

I still have the same warning, my code is:

obj.row_start();
obj.format_cell(data:
"OBJECTIFS :" , overrides: "font_face=Calibri just=left font_weight=bold color=cx338AFF font_size=10pt width=2.6 cm");
obj.format_cell(data: %sysfunc(quote(%superq(PROFILE))) , overrides: "font_face=Calibri just=left color=black font_size=10pt ");
obj.row_end();

Re: Sign % in text of macro variable

SASdevAnneMarie — Tue, 04 Aug 2020 12:30:40 GMT

Thank you!

I still have the same warning, my code is:

obj.row_start();
obj.format_cell(data:
"OBJECTIFS :" , overrides: "font_face=Calibri just=left font_weight=bold color=cx338AFF font_size=10pt width=2.6 cm");
obj.format_cell(data: %sysfunc(quote(%superq(PROFILE))) , overrides: "font_face=Calibri just=left color=black font_size=10pt ");
obj.row_end();

Re: Sign % in text of macro variable

SASdevAnneMarie — Tue, 04 Aug 2020 12:31:29 GMT

Thank you!

Re: Sign % in text of macro variable

yabwon — Tue, 04 Aug 2020 12:44:25 GMT

hmmm..

try with %qsysfunc()

data _null_;
  call symputX('PROFILE', 'ne devra représenter plus de 20 %du profil de gestion', "G");
run;

%put %qsysfunc(quote(%superq(PROFILE)));

Re: Sign % in text of macro variable

Kurt_Bremser — Tue, 04 Aug 2020 12:52:28 GMT

The first argument to %SYSFUNC must be a data step function.

Belay that, somehow the coffee must not have worked today.

Re: Sign % in text of macro variable

SASdevAnneMarie — Tue, 04 Aug 2020 13:48:35 GMT

Hello Kurt,
Thank you for your answer!
I didn't understand , %sysfunc(quote(%superq(PROFILE_NAME))) worked in my code for another problem.
I can't use %sysfunc?

Re: Sign % in text of macro variable

SASdevAnneMarie — Tue, 04 Aug 2020 14:11:02 GMT

Hello, thank you!
%qsysfunc need a put, beacause I get the error:
ERROR 22-322: Syntax error, expecting one of the following: a name, a quoted string, a numeric constant, a datetime constant,
a missing value, arrayname, (, +, -, INPUT, NOT, PUT, ^, _NEW_, ~.
I can't write a put, beacause I have an ods object code:

obj.row_start();
obj.format_cell(data:
"OBJECTIFS :" , overrides: "font_face=Calibri just=left font_weight=bold color=cx338AFF font_size=10pt width=2.6 cm");
obj.format_cell(data: %sysfunc(quote(%superq(PROFILE))) ,
overrides: "font_face=Calibri just=left color=black font_size=10pt ");
obj.row_end();

Re: Sign % in text of macro variable

Tom — Tue, 04 Aug 2020 15:39:11 GMT

Not sure what this statement is. Why does the first line end in a comma and not a semi-colon? So assuming you want to run this statement:

obj.format_cell(data: %sysfunc(quote(%superq(PROFILE))) 
               ,overrides: "font_face=Calibri just=left color=black font_size=10pt ")
;

Does that statement allow you to use single quotes instead of double quotes? Those will prevent the macro process from trying to evaluate the % and & triggers in the string.

obj.format_cell(data: %sysfunc(quote(%superq(PROFILE),%str(')))
               ,overrides: "font_face=Calibri just=left color=black font_size=10pt ")
;

Also does the syntax of that statement allow a variable or function instead of a string literal?

obj.format_cell(data: symget('PROFILE') 
               ,overrides: "font_face=Calibri just=left color=black font_size=10pt ")
;

Re: Sign % in text of macro variable

yabwon — Tue, 04 Aug 2020 15:02:42 GMT

and how about this:

data _null_;
  call symputX('PROFILE', 'ne devra représenter plus de 20 %du profil de gestion', "G");
run;

obj.row_start();
obj.format_cell(data:
"OBJECTIFS :" , overrides: "font_face=Calibri just=left font_weight=bold color=cx338AFF font_size=10pt width=2.6 cm");
obj.format_cell(data: %str(%')%superq(PROFILE)%str(%') ,
overrides: "font_face=Calibri just=left color=black font_size=10pt ");
obj.row_end();

for the format_cell data portion(according to the doc) can be enclosed in single quotes.

Bart

Re: Sign % in text of macro variable

yabwon — Tue, 04 Aug 2020 15:21:16 GMT

or approach with `_temporary_variable_`?

data _null_;
  call symputX('PROFILE', 'ne devra représenter plus de 20 %du profil de gestion', "G");
run;


filename out "%sysfunc(pathname(WORK))";
ods html close;
ods html path=Out file="test.html";

data _null_;

  dcl odsout obj();
  obj.table_start();

  _temporary_variable_ = symget("PROFILE");
  drop _temporary_variable_;

  obj.row_start();
  obj.format_cell(data: "OBJECTIFS :", 
    overrides: "font_face=Calibri just=left font_weight=bold color=cx338AFF font_size=10pt width=2.6 cm");
  obj.format_cell(data: _temporary_variable_,
    overrides: "font_face=Calibri just=left color=black font_size=10pt ");
  obj.row_end();


  obj.table_end();
run;
ods html close;
ods html;

Bart

Re: Sign % in text of macro variable

SASdevAnneMarie — Wed, 05 Aug 2020 09:46:25 GMT


proc import 
	datafile="XXXXXXX\Exemple.xlsx"
	out=RESULTAT
	replace dbms=xlsx;
	getnames=yes;
run;


%macro publi;

	DATA _null_;
		SET RESULTAT end=eof;

		IF eof THEN
			DO;
				CALL SYMPUT('nombre',put(_N_,8.));
			END;
	run;


	%do i=1 %to &nombre.;

		/*****************************************************/
		/*****Narratifs rélatids aus données calculées *******/
		/*****************************************************/
		data _NULL_;
			set RESULTAT (obs=&i);
			call symputx('PROFILE',PROFILE_NAME);
			call symputx('PROFILE_OBJECTIVES',PROFILE_OBJECTIVES);
		run;
	
       OPTION NODATE NONUMBER;
		OPTIONS PAPERSIZE=LETTER;
		OPTIONS TOPMARGIN=0 in BOTTOMMARGIN=0 in LEFTMARGIN=0 in RIGHTMARGIN=0 in;
		ODS NORESULTS;
		ODS PDF FILE = "XXXXXXXX\Doc_&i..pdf" dpi=1800;
		ODS ESCAPECHAR = "^";

		data _NULL_;
			declare odsout obj();
			obj.layout_absolute(overrides :"borderwidth=0");
			obj.line(style_attr: "bordercolor=blue", size:'0.8mm');
            obj.table_start(name:

			"table1",
			label: "Notre Première Table",
			overrides: "width=19 cm frame=void rules=none" );

			obj.row_start();
	obj.format_cell(data:

			"NOM:" ,
			overrides: "font_face=Calibri just=left font_weight=bold color=blue font_size=10pt");
	obj.format_cell(data:

			%sysfunc(quote(%superq(PROFILE))) ,
			overrides: "just=left font_face=Calibri color=black font_size=10pt");
			obj.row_end();
			obj.row_start();
	obj.format_cell(data:
			"OBJECTIFS :" ,	overrides: "font_face=Calibri just=left font_weight=bold color=blue font_size=10pt width=2.5 cm");
	obj.format_cell(data:
			"&PROFILE_OBJECTIVES." ,overrides: "font_face=Calibri just=left color=black font_size=10pt width=15 cm");
			obj.row_end();
			obj.table_end();
			obj.layout_end();
		Run;


		ODS PDF CLOSE;
	%end;
%mend;

%publi;

Re: Sign % in text of macro variable

SASdevAnneMarie — Wed, 05 Aug 2020 09:49:30 GMT

Hello experts,
I added the code.
I can't understand why %sysfunc(quote(%superq(&PROFILE_OBJECTIVES.))) doesn't works and I get the warning: WARNING: Apparent invocation of macro DU not resolved.

Thank you!

Re: Sign % in text of macro variable

SASdevAnneMarie — Wed, 05 Aug 2020 09:51:01 GMT

Hello Tom,

Thank you for your suggestions.
Unfortunately it doesn't work. (
I added the code and xlsx file.

Best regards,
Marie

Re: Sign % in text of macro variable

yabwon — Wed, 05 Aug 2020 11:57:39 GMT

Hi,

the

%sysfunc(quote(%superq(PROFILE)))

is giving the warning because it resolves to the following text

"ne devra représenter plus de 20 %du profil de gestion"

including double quotation symbols. So, since text is surrounded by double quotes, SAS[macro processor + wordscaner] scans it and it treats % as macro trigger.

Simpler example would be:

data _null_;
 x = "%ABC";
 y = '%EFG';
run;

in the log we will see warning for %ABC macro but not for %EFG.

If you would use version proposed by @Tom :

%sysfunc(quote(%superq(PROFILE), %str(%')))

the resolved text would be:

'ne devra représenter plus de 20 %du profil de gestion'

but with single quotation marks hence SAS[macro processor + wordscaner] won't treat % as macro trigger.

So Doc. references:

https://documentation.sas.com/?docsetId=mcrolref&docsetTarget=n0700fspmubii5n1vecutttwz93n.htm&docsetVersion=9.4&locale=en#n1uvx72itk1akhn0zy4d67ec4ky8

Hope it helps

Bart

Re: Sign % in text of macro variable

SASdevAnneMarie — Wed, 05 Aug 2020 13:34:26 GMT

Thank you!
I see, but this is not working, I need the double quotation in my code: "&PROFILE_OBJECTIVES." 😞

Best regards,
Marie

Re: Sign % in text of macro variable

yabwon — Wed, 05 Aug 2020 14:30:24 GMT

No, you don't need double quotations. Documentation says that it doesn't have to be a text string but it could be a character variable (https://documentation.sas.com/?docsetId=odsadvug&docsetTarget=p12q0pykppxbz8n1200luexgbz4t.htm&docsetVersion=9.4&locale=en)

From the doc:

DATA: <'string' | number | character-variable | numeric-variable>

specifies the data to display.

'string'

specifies a text string.

number

specifies a numeric value.

character-variable	specifies the name of a character variable. The value of the character variable from the input data set is written to the output.
numeric-variable	specifies the name of a numeric variable. The value of the numeric variable from the input data set is written to the output.

See the code below which uses temporary_variables to solve the issue.

Btw.

this code can be done more efficient:

DATA _null_;
		SET RESULTAT end=eof;

		IF eof THEN
			DO;
				CALL SYMPUT('nombre',put(_N_,8.));
			END;
	run;

with:

DATA _null_;
 CALL SYMPUTX('nombre',nobs);
 stop;		 
 SET RESULTAT nobs=nobs;
run;

Here is your code modified with temporary variables.

data RESULTAT;
  PROFILE_NAME = 'ne devra représenter plus de 20 %du profil de gestion';
  PROFILE_OBJECTIVES = "A B C D";
  output;
run;

%macro publi;

	DATA _null_;
		SET RESULTAT end=eof;

		IF eof THEN
			DO;
				CALL SYMPUT('nombre',put(_N_,8.));
			END;
	run;


	%do i=1 %to &nombre.;

		/*****************************************************/
		/*****Narratifs rélatids aus données calculées *******/
		/*****************************************************/
		data _NULL_;
			set RESULTAT (obs=&i);
			call symputx('PROFILE',PROFILE_NAME);
			call symputx('PROFILE_OBJECTIVES',PROFILE_OBJECTIVES);
		run;
	
       OPTION NODATE NONUMBER;
		OPTIONS PAPERSIZE=LETTER;
		OPTIONS TOPMARGIN=0 in BOTTOMMARGIN=0 in LEFTMARGIN=0 in RIGHTMARGIN=0 in;
		ODS NORESULTS;
		ODS PDF FILE = "%sysfunc(pathname(WORK))\Doc_&i..pdf" dpi=1800;
		ODS ESCAPECHAR = "^";

		data _NULL_;

      /* TEMPORARY variables to replace MACRO variables */
      _temporary_variable_1 = symget('PROFILE');
      _temporary_variable_2 = symget('PROFILE_OBJECTIVES');
      drop _temporary_variable_:;
      
			declare odsout obj();
			obj.layout_absolute(overrides :"borderwidth=0");
			obj.line(style_attr: "bordercolor=blue", size:'0.8mm');
            obj.table_start(name:

			"table1",
			label: "Notre Première Table",
			overrides: "width=19 cm frame=void rules=none" );

			obj.row_start();
	obj.format_cell(data:

			"NOM:" ,
			overrides: "font_face=Calibri just=left font_weight=bold color=blue font_size=10pt");
	obj.format_cell(data: _temporary_variable_1,
			overrides: "just=left font_face=Calibri color=black font_size=10pt");
			obj.row_end();
			obj.row_start();
	obj.format_cell(data:
			"OBJECTIFS :" ,	overrides: "font_face=Calibri just=left font_weight=bold color=blue font_size=10pt width=2.5 cm");
	obj.format_cell(data:
			_temporary_variable_2 ,overrides: "font_face=Calibri just=left color=black font_size=10pt width=15 cm");
			obj.row_end();
			obj.table_end();
			obj.layout_end();
		Run;


		ODS PDF CLOSE;
	%end;
%mend;

%publi;

All the best

Bart