topic Re: How to express the p value when <.0001 in %IF statement. in SAS Programming

How to express the p value when <.0001 in %IF statement.

RosieSAS — Wed, 29 Jul 2020 18:39:32 GMT

What I'm trying to do is to compare means after treatment p<0.05. First I saved p value through PROC SQL, then according to the p value to decide if needing to group the means or not. However, when p<.0001, the macro function %lsmeansOutput(P) always runs without LINES option as p>=0.05. When there is an exact p value<0.05, for example p=0.025, the macro function works correctly to show the mean grouping results.

Is there anyone can help me figure out the reason?

proc sql ; ** obtain p-value of trt;
	select ProbF as intP into :intP 
	from Fixedp	where Effect='Treatment';
run;

%macro lsmeansOutput (P);
  %if &P<0.05 %then %do;
    proc plm restore=&response.out;
	ods exclude diffplot meanplot classlevels;
        lsmeans treatment/lines;
    run;
  %end;
  %else %do;
    proc plm restore=&response.out;
	ods exclude diffplot meanplot classlevels;
        lsmeans treatment;
    run;    
  %end;    
%mend lsmeansOutput;

Thanks in advance!

Re: How to express the p value when <.0001 in %IF statement.

Reeza — Wed, 29 Jul 2020 19:03:29 GMT

When you extract the value from the db make sure to get the raw number not the formatted value. And when doing numerical comparisons with decimals wrap it in %SYSEVALF.

%if %sysevalf(&P<0.05) %then %do;

@RosieSAS wrote:

What I'm trying to do is to compare means after treatment p<0.05. First I saved p value through PROC SQL, then according to the p value to decide if needing to group the means or not. However, when p<.0001, the macro function %lsmeansOutput(P) always runs without LINES option as p>=0.05. When there is an exact p value<0.05, for example p=0.025, the macro function works correctly to show the mean grouping results.

Is there anyone can help me figure out the reason?
proc sql ; ** obtain p-value of trt;
	select ProbF as intP into :intP 
	from Fixedp	where Effect='Treatment';
run;

%macro lsmeansOutput (P);
  %if &P<0.05 %then %do;
    proc plm restore=&response.out;
	ods exclude diffplot meanplot classlevels;
        lsmeans treatment/lines;
    run;
  %end;
  %else %do;
    proc plm restore=&response.out;
	ods exclude diffplot meanplot classlevels;
        lsmeans treatment;
    run;    
  %end;    
%mend lsmeansOutput;
Thanks in advance!

Re: How to express the p value when <.0001 in %IF statement.

RosieSAS — Wed, 29 Jul 2020 19:10:41 GMT

Thanks for your reply! However, it doesn't work. It still only outputs the means.

Re: How to express the p value when <.0001 in %IF statement.

Reeza — Wed, 29 Jul 2020 19:20:56 GMT

Well...what is P? Where is it created? You create a variable called IntP but I don't see a P. Is that a typo or oversight?

Re: How to express the p value when <.0001 in %IF statement.

RosieSAS — Wed, 29 Jul 2020 19:52:17 GMT

When I call the Macro, I used % lsmeansOutput (intP), so that should not be a problem.

Re: How to express the p value when <.0001 in %IF statement.

Tom — Wed, 29 Jul 2020 19:42:14 GMT

If you literally ran:

%macro lsmeansOutput (intP);

Then you started redefining the macro and SAS is going to take all input as part of the macro until you submit

%mend;

If instead you called the macro with intP as the input like this:

%lsmeansOutput (intP)

Then you are asking %sysevalf() to compare the letter i to the digit 0 and letter are always "larger" than digits.

Make sure to pass the VALUE of the macro variable in the macro call.

%lsmeansOutput(&intP)

Also make sure that your source variable ProbF is numeric an not character. If it is character and has a value like <0.001 then you are going to give %sysevalf() a very strange expression to evaluate.

Re: How to express the p value when <.0001 in %IF statement.

RosieSAS — Wed, 29 Jul 2020 19:44:24 GMT

I also tried the code below, the result in Log window is "xvalue is 0, intP value is <.0001". Any ideas?

%let x=%sysevalf(&intP<0.05);
%put xvalue is &x, intP value is &intP;

Re: How to express the p value when <.0001 in %IF statement.

RosieSAS — Wed, 29 Jul 2020 19:49:15 GMT

Thanks for your reply! No matter using &intP or intP, the results are the same here. ProbF is a numeric, the format is pvalue6.4.

Re: How to express the p value when <.0001 in %IF statement.

Tom — Wed, 29 Jul 2020 20:10:35 GMT

You are not going to get the less than sign into the macro from a numeric variable with the code you showed. It does not matter what format is attached to the variable.

correction Actually it will put the formatted value, with leading spaces. Remove the format or use a different format. Use the TRIMMED keyword to avoid the leading spaces.

Anyway IF your macro variable has values that either start with < or 0 then you can just eliminate the first character and it should work.

884   %let x=<0.001 ;
885   %let y=0.10 ;
886   %let z=0.01 ;
887   %put &x -> %sysevalf(0.05>%substr(&x,2));
<0.001 -> 1
888   %put &y -> %sysevalf(0.05>%substr(&y,2));
0.10 -> 0
889   %put &z -> %sysevalf(0.05>%substr(&z,2));
0.01 -> 1

Re: How to express the p value when <.0001 in %IF statement.

Reeza — Wed, 29 Jul 2020 21:03:23 GMT

@RosieSAS wrote:
Thanks for your reply! No matter using &intP or intP, the results are the same here. ProbF is a numeric, the format is pvalue6.4.

First line in my response:

When you extract the value from the db make sure to get the raw number not the formatted value.

proc sql ; ** obtain p-value of trt;
	select ProbF format=12.5 as intP into :intP 
	from Fixedp	where Effect='Treatment';
run;

Re: How to express the p value when <.0001 in %IF statement.

ballardw — Wed, 29 Jul 2020 22:51:04 GMT

Go back to where you create your INTp and fix it. You have created a character value that includes a < sign so the comparison fails.

If a variable has an assigned format, such as pvalue6.4 when you use the Proc sql select into the default format is applied. You need to make sure that the format used doesn't place any odd characters in the result.

data junk;
  probf = 0.00000567;
  format probf pvalue6.4;
run;
/* Wrong*/
proc sql ; ** obtain p-value of trt;
	select ProbF as intP into :intP 
	from junk;
quit;

%put IntP is: &intp.;
/* somewhat better*/
proc sql ; ** obtain p-value of trt;
	select ProbF format=8.6 as intP into :intP 
	from junk;
quit;

%put IntP is: &intp.;

you get x=0 because the comparison is false.

You are evaluating %syevalf( <.0001<0.05 )

%let intp = <.0001;
%let x=%sysevalf(&intP<0.05);
%put xvalue is &x, intP value is &intP;


%let nump = 0.0001;
%let x=%sysevalf(&numP<0.05);
%put xvalue is &x, NumP value is &numP;

Re: How to express the p value when <.0001 in %IF statement.

RosieSAS — Thu, 30 Jul 2020 00:08:53 GMT

Thanks for all your replies!

When I specify the format of intP as format12.5 or format8.6 where intP<.0001, the print value is 0.00000. Then I tried the following code, and the result is 1. But I don't know why it still only ran the LSMEANS without LINES part. Below is the results from LOG window when using format8.6 in PROC SQL.

252 %put &intP is intP;
0.000000 is intP

253 %put %sysevalf(&intP<.05) is the logic;
1 is the logic

I tried @Tom 's method using %substr() without using FORMAT, and it works. The code is as following.

proc sql noprint; ** obtain p-value of trt;
	select ProbF as intP into :intP 
	from Fixedp where Effect='Treatment';
  run;

%macro lsmeansOutput(P);
   %if %sysevalf(%substr(&intP,2)<.05) %then %do;
    proc plm restore=&response.out;
	ods exclude diffplot meanplot classlevels;
    lsmeans treatment/lines adjust=Tukey;
    run;
   %end;
  %else %do;
    proc plm restore=&response.out;
	ods exclude diffplot meanplot classlevels;
    lsmeans treatment;
    run;    
  %end;    
%mend lsmeansOutput;

 %lsmeansOutput(intP);

Thanks again for all the help! I got a lot.

Re: How to express the p value when <.0001 in %IF statement.

Reeza — Thu, 30 Jul 2020 00:28:26 GMT

You do not need the SUBSTR(). The value may be 0.0000 and the only difference between the outputs is the lines/adjust option. If you're not sure if the %IF/%THEN statements are working, remove the code and add explicit %PUT statements to test your logic first.

Re: How to express the p value when <.0001 in %IF statement.

RosieSAS — Thu, 30 Jul 2020 13:25:33 GMT

Thanks for all the suggestions. I found an interesting problem that %sysevalf(&P<0.05 ) gave me different results for the same value of &P. The detail is, the P value is very small, after using format8.6 in proc sql, it shows 0.000000. When I ran %put alone, the result was 1.

However, when I ran the whole %lsmansOutput(P), the result was 0. Anyone knows the reason? Thanks!

395  %put Fail %sysevalf(&P<0.05);
Fail 1
396  %macro lsmeansOutput(P);
397     %if %sysevalf(&P<0.05) %then %do;
398      proc plm restore=&response.out;
399      ods exclude diffplot meanplot classlevels;
400      lsmeans treatment/lines adjust=Tukey;
401      run;
402      %put Success %sysevalf(&P<0.05);
403     %end;
404    %else %do;
405      proc plm restore=&response.out;
406      ods exclude diffplot meanplot classlevels;
407      lsmeans treatment;
408      run;
409      %put Fail %sysevalf(&P<0.05);
410    %end;
411  %mend lsmeansOutput;
412
413  %lsmeansOutput(P);
NOTE: PROCEDURE PLM used (Total process time):
      real time           0.01 seconds
      cpu time            0.01 seconds


Fail 0

I also tried simplified code, the %put also gave different results. I guess when P value is very small, or like 0.000000, the %sysevalf automatically treats P as a character variable. Please verify, thanks!

478  %macro lsmeansOutput(P);
479    %if %sysevalf(&P <.05) %then %do;
480        %put p=&P;
481    %end;
482    %else %do;
483        %put met else condition=&P;
484    %end;
485  %mend;

486  %lsmeansOutput(P);
met else condition=P
487  %put p=&P;
p=0.000000

Re: How to express the p value when <.0001 in %IF statement.

Kurt_Bremser — Thu, 30 Jul 2020 13:21:28 GMT

You use the literal string P instead of the macro variable reference &P when calling the macro.

With the macro reference, the code works:

%let p=0.00000000001;

%put Fail %sysevalf(&P<0.05);

%macro lsmeansOutput(P);
   %if %sysevalf(&P<0.05) %then %do;
     %put Yes branch;
   %end;
  %else %do;
    %put No branch;
  %end;
%mend lsmeansOutput;

%lsmeansOutput(&P);

Re: How to express the p value when <.0001 in %IF statement.

Tom — Thu, 30 Jul 2020 13:23:36 GMT

You are calling the macro with just the letter P as the value, not the value of the macro variable P that you tested before you defined the macro and called. Add the value of the local macro variable P to your %PUT statements inside your macro definition so you can see what you actually tested.

The letter P is NOT less than the digit 0. Howver if you have told SAS to treat P when reading text into numbers as meaning special missing value .P by including it in the list of letters used in a MISSING statement then the test will find that P is < 0.05 since it will actually test if .P < 0.05 instead and all missing values are less than all actual numbers.

Re: How to express the p value when <.0001 in %IF statement.

RosieSAS — Thu, 30 Jul 2020 14:19:35 GMT

Thanks for all your inputs, without your helps, I couldn't figure it out. Here it the code to solve my problem.

Using %lsmeansOutput(&P) instead of %lsmeansOutput(P) in when calling this macro function after format P to FORMAT 12.5.

proc sql ; ** obtain p-value of trt;
	select ProbF format 12.5 as P into :P 
	from Fixedp	where Effect='Treatment';
  run;

%macro lsmeansOutput(P);
   %if %sysevalf(&P<.05) %then %do;
    proc plm restore=&response.out;
      lsmeans treatment/lines adjust=Tukey;
    run;
	%put Yes branch;
   %end;
  %else %do;
    proc plm restore=&response.out;
      lsmeans treatment;
    run;    
	%put No branch;
  %end;    
%mend lsmeansOutput;
  %lsmeansOutput(&P);

Re: How to express the p value when <.0001 in %IF statement.

Kurt_Bremser — Thu, 30 Jul 2020 14:05:30 GMT

Your second example provides the expected result while being completely wrong 😉

You take the substring of a string with the length of 1 ("P"), starting at position 2; this results in an empty value, which is of course smaller than anything else.

Re: How to express the p value when <.0001 in %IF statement.

Tom — Thu, 30 Jul 2020 14:08:48 GMT

The last call

%lsmeansOutput(P)

cannot work.

You have passed the letter P to the macro. If you macro expected the NAME of a macro variable that might work, but even that could not work in this case since the global macro variable has the same name as the local macro variable (the parameters listed in the %macro statement are local macro variables). Inside the macro the local macro variables will hide any macro variables with the same name in any outer scope.

Re: How to express the p value when <.0001 in %IF statement.

RosieSAS — Thu, 30 Jul 2020 14:11:16 GMT

Your inference makes sense, but when p>0.05, it did run the %else condition without grouping results. I don't know how that happened. Do you mean &y should be used instead of y for every macro function %function(y)?