topic Re: remove ending "-XX" in SAS Programming

remove ending "-XX"

jl2978 — Tue, 28 Jul 2020 15:27:14 GMT

I have a variable with values like

TUXEDO PARTNERS INC-AT KEYES HOWARD AUTO DLRHSPS-PX SPRING HILL FORD INC-CH MEGASTAR INC BRANDON CHRY-PLYM INC-TM

The ending "-XX" is the city abbreviations. I want to remove this part.

It can't be coded as removing characters after "-" because "-" can appear in the middle of the string. Or remove the last three characters because some values don't have ending "-XX".

Any tips on dealing with this situation?

Thanks!

Re: remove ending "-XX"

Reeza — Tue, 28 Jul 2020 15:31:58 GMT

Check if the 3rd to last character is a - and then remove it?

if substr(variable, length(variable)-3, 1) = '-' then want = substr(variable, length(variable)-3);

Re: remove ending "-XX"

novinosrin — Tue, 28 Jul 2020 15:33:11 GMT

data have;
input str $40.;
cards;
TUXEDO PARTNERS INC-AT
KEYES HOWARD AUTO DLRHSPS-PX
SPRING HILL FORD INC-CH
MEGASTAR INC
BRANDON CHRY-PLYM INC-TM
;

data want;
 set have;
 _n_=findc(str,'-','b');
 if _n_ then want=substr(str,1,_n_);
 else want=str;
run;

Re: remove ending "-XX"

smantha — Tue, 28 Jul 2020 16:40:54 GMT

I hope you did not mean _n_ 🙂

Re: remove ending "-XX"

mklangley — Tue, 28 Jul 2020 17:05:43 GMT

Using PRXMATCH to determine if the string ends with "-XX":

data have;
    input str $40.;
    cards;
    TUXEDO PARTNERS INC-AT
    KEYES HOWARD AUTO DLRHSPS-PX
    SPRING HILL FORD INC-CH
    MEGASTAR INC
    BRANDON CHRY-PLYM INC-TM
    TEST-ABC-DEF-XX
;
run;

data want;
   set have;
   if prxmatch('/(\w+)-\w\w\s*$/', str)
       then want = substr(str, 1, length(str)-3);
   else want=str;
run;

Re: remove ending "-XX"

singhsahab — Tue, 28 Jul 2020 17:18:38 GMT

data have;
input str $40.;
cards;
TUXEDO PARTNERS INC-AT
KEYES HOWARD AUTO DLRHSPS-PX
SPRING HILL FORD INC-CH
MEGASTAR INC
BRANDON CHRY-PLYM INC-TM
;
run;
data want;
set have;
rev_str=(strip(reverse(str)));
new_str=strip(reverse(substr(rev_str,index(rev_str,'-')+1)));
drop rev_str;
run;

Re: remove ending "-XX"

ballardw — Tue, 28 Jul 2020 22:12:56 GMT

@smantha wrote:

I hope you did not mean _n_ 🙂

@novinosrin seems to like playing with fire and often uses a variable _n_ instead of considering the possible confusion with the SAS automatic variable of the same name.

Re: remove ending "-XX"

Reeza — Wed, 29 Jul 2020 02:05:08 GMT

Most likely picked up from some of the older programmers I think but not something I would recommend doing at all 🙂

Re: remove ending "-XX"

Ksharp — Wed, 29 Jul 2020 12:21:35 GMT

data have;
input str $40.;

want=prxchange('s/-\w\w$//',-1,strip(str));

cards;
TUXEDO PARTNERS INC-AT
KEYES HOWARD AUTO DLRHSPS-PX
SPRING HILL FORD INC-CH
MEGASTAR INC
BRANDON CHRY-PLYM INC-TM
;

Re: remove ending "-XX"

Ksharp — Wed, 29 Jul 2020 12:26:11 GMT

data have;
input str $40.;

want=prxchange('s/-\w\w\s*$//',1,str);

cards;
TUXEDO PARTNERS INC-AT
KEYES HOWARD AUTO DLRHSPS-PX
SPRING HILL FORD INC-CH
MEGASTAR INC
BRANDON CHRY-PLYM INC-TM
;