topic Re: Getinng the first day of quarter with intnx function giving odd results in SAS Programming

Getinng the first day of quarter with intnx function giving odd results

sasuser381 — Fri, 24 Jul 2020 12:11:40 GMT

I tried to get the first day of current quarter with this code.

%let q1=intnx('qtr', today(),0,'b');

%put &q1;

This gives me the result:

01JAN1960:06:08:17.000 instead of 01JUN2020:00:00:00

Re: Getinng the first day of quarter with intnx function giving odd results

sasuser381 — Fri, 24 Jul 2020 12:15:01 GMT

Edit:

It gives me the result 01JAN1960:06:08:17

Re: Getinng the first day of quarter with intnx function giving odd results

PaigeMiller — Fri, 24 Jul 2020 12:27:53 GMT

I cannot see how the code you show produces anything that looks like a date or datetime value. You need a %sysfunc or two. Are you sure that is the exact code you are using?

This code works for me:

%let q1=%sysfunc(intnx(qtr,%sysfunc(today()),0,b));
%put &=q1;

Re: Getinng the first day of quarter with intnx function giving odd results

sasuser381 — Fri, 24 Jul 2020 12:39:30 GMT

This is the whole code:

%let q1=intnx('qtr', today(),0,'b');
%put &q1;

DATA Q1CHECK;
Q1=&Q1; FORMAT Q1 DATETIME16.;
RUN;

Re: Getinng the first day of quarter with intnx function giving odd results

PaigeMiller — Fri, 24 Jul 2020 12:54:51 GMT

You want to use a date format, not a datetime format.

Re: Getinng the first day of quarter with intnx function giving odd results

sasuser381 — Fri, 24 Jul 2020 12:59:16 GMT

Well i need datetime format actualy as an output. How could i do that? Obviously not this way i did.

Re: Getinng the first day of quarter with intnx function giving odd results

Tom — Fri, 24 Jul 2020 13:51:20 GMT

@sasuser381 wrote:
Well i need datetime format actualy as an output. How could i do that? Obviously not this way i did.

You need to use datetime values (number of seconds) not date values (number of days) with the DATETIME format. Use the DTQTR interval instead of the QTR interval when working with seconds instead of days.

340   data _null_;
341     now=datetime();
342     qtr=intnx('dtqtr',now,0,'b');
343     put (now qtr) (datetime19.);
344   run;

 24JUL2020:09:49:55 01JUL2020:00:00:00

Re: Getinng the first day of quarter with intnx function giving odd results

smantha — Fri, 24 Jul 2020 15:03:20 GMT

In SAS macro code you need to wrap datastep function in %sysfunc unless you have macro equivalent such as %scan. In your case it will be

%let q1=intnx('qtr', %sysfunc(today()) ,0,'b');

%put &q1;

Re: Getinng the first day of quarter with intnx function giving odd results

Reeza — Fri, 24 Jul 2020 15:21:50 GMT

1. Functions need to be wrapped in %SYSFUNC()

2. For datetime variables the increment needs to start with DT

3. When using functions within macro code, you do not need quotes.

4. TODAY() returns a DATE variable, if you want DATETIME use DATETIME() function instead.

%let q1=%sysfunc(intnx(dtqtr, %sysfunc(datetime()), 0, b), datetime.);

%put &q1.;

Results:

 1          OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;
 68         
 69         %let q1=%sysfunc(intnx(dtqtr, %sysfunc(datetime()), 0, b), datetime.);
 70         
 71         %put &q1.;
 01JUL20:00:00:00
 72         
 73         OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;
 83

@sasuser381 wrote:

I tried to get the first day of current quarter with this code.
%let q1=intnx('qtr', today(),0,'b');

%put &q1;
This gives me the result:

01JAN1960:06:08:17.000 instead of 01JUN2020:00:00:00

Re: Getinng the first day of quarter with intnx function giving odd results

ghosh — Fri, 24 Jul 2020 18:06:11 GMT


%let q1=%sysfunc(intnx(qtr,%sysfunc(today()),0,b),datetime20.);

/* %let q1=intnx('qtr', today(),0,'b'); */

%put &q1;