topic Re: How do I export a newly created text file to a zip file? in SAS Programming

How do I export a newly created text file to a zip file?

InspectahDex — Tue, 21 Jul 2020 17:13:36 GMT

I have this code:

proc export data=finaldata
outfile="&ExportLoc./finaldata_%sysfunc(today(),yymmddN.)%sysfunc(hour(%sysfunc(time())),z2.)%sysfunc(minute(%sysfunc(time())),z2.)%sysfunc(second(%sysfunc(time())),z2.)_123.txt"
dbms=dlm replace;
delimiter='|';
run;

I want to take what is created from there to export out into a zipped file. I have the below code but the log says it can't find the physical file because it doesn't exist. What am I missing?

ods package(newzip) open nopf;
ods package(newzip) add file="&ExportLoc./finaldata_%sysfunc(today(),yymmddN.)%sysfunc(hour(%sysfunc(time())),z2.)%sysfunc(minute(%sysfunc(time())),z2.)%sysfunc(second(%sysfunc(time())),z2.)_123.txt";
ods package(newzip) publish archive
properties(
archive_name="finaldata_%sysfunc(today(),yymmddN.)%sysfunc(hour(%sysfunc(time())),z2.)%sysfunc(minute(%sysfunc(time())),z2.)%sysfunc(second(%sysfunc(time())),z2.)_123.zip"
archive_path="&ExportLoc."
);
ods package(newzip) close;

Re: How do I export a newly created text file to a zip file?

Reeza — Tue, 21 Jul 2020 18:19:54 GMT

Post the full log will help. But since you're using time and date, my guess is that the time doesn't match exactly anymore. If you run it a minute later your file will have a different name so you cannot use dynamic time references when you need to do something list. I would suggest creating the filename once and then using it through the process.


%let file_export = &ExportLoc./finaldata_%sysfunc(today(),yymmddN.)%sysfunc(hour(%sysfunc(time())),z2.)%sysfunc(minute(%sysfunc(time())),z2.)%sysfunc(second(%sysfunc(time())),z2.)_123;


proc export data=finaldata
outfile= "&file_export..txt"
dbms=dlm replace;
delimiter='|';
run;

ods package(newzip) open nopf;
ods package(newzip) add file="&file_export..txt";
ods package(newzip) publish archive
properties(
archive_name="&file_export..zip"
archive_path="&ExportLoc."
);
ods package(newzip) close;

@InspectahDex wrote:

I have this code:

proc export data=finaldata
outfile="&ExportLoc./finaldata_%sysfunc(today(),yymmddN.)%sysfunc(hour(%sysfunc(time())),z2.)%sysfunc(minute(%sysfunc(time())),z2.)%sysfunc(second(%sysfunc(time())),z2.)_123.txt"
dbms=dlm replace;
delimiter='|';
run;

I want to take what is created from there to export out into a zipped file. I have the below code but the log says it can't find the physical file because it doesn't exist. What am I missing?

ods package(newzip) open nopf;
ods package(newzip) add file="&ExportLoc./finaldata_%sysfunc(today(),yymmddN.)%sysfunc(hour(%sysfunc(time())),z2.)%sysfunc(minute(%sysfunc(time())),z2.)%sysfunc(second(%sysfunc(time())),z2.)_123.txt";
ods package(newzip) publish archive
properties(
archive_name="finaldata_%sysfunc(today(),yymmddN.)%sysfunc(hour(%sysfunc(time())),z2.)%sysfunc(minute(%sysfunc(time())),z2.)%sysfunc(second(%sysfunc(time())),z2.)_123.zip"
archive_path="&ExportLoc."
);
ods package(newzip) close;

Re: How do I export a newly created text file to a zip file?

yabwon — Tue, 21 Jul 2020 18:27:22 GMT

Hi,

How about by using filename ZIP? By the way I suggest you to use proc format to have "easier" file naming:

/* Assuming we have this: */
%let ExportLoc = %sysfunc(pathname(work));

data finaldata;
  set sashelp.class;
run;


/* to make naming textfie easier! */
proc format; 
  picture  myDatetime (default=14)
    other='%Y%0m%0d%0H%0M%0S' (datatype=datetime)
  ;
run;


/* reference to ZIP device */
filename f ZIP "&ExportLoc./newzip.zip" member = "finaldata_%sysfunc(datetime(), myDatetime.)_123.txt";
proc export data=finaldata
    outfile=f
    dbms=dlm 
    replace;
  delimiter='|';
run;

Bart

Re: How do I export a newly created text file to a zip file?

InspectahDex — Tue, 21 Jul 2020 20:26:42 GMT

Thank you! That worked and solved my problem! Also thanks for the proc format tip!

Re: How do I export a newly created text file to a zip file?

InspectahDex — Tue, 21 Jul 2020 20:28:21 GMT

Because the code will be part of an automated process, I need to do this all in one step without having to run the entire program twice.

Re: How do I export a newly created text file to a zip file?

Reeza — Wed, 22 Jul 2020 01:46:51 GMT

You should not have to run my solution twice.

The issue with your solution is a matter of timing. If you run it at 11:59:58 (11:59AM) the text file has the 59 as minutes. If the next step is run at 12:00:01 (12:00PM) you'll have 00 as the minutes so that file doesn't exist. So you need to create the filename once and fix it, not calculate it dynamically throughout your code.