topic Conversion of MRN numbers in a data set in SAS Programming

Conversion of MRN numbers in a data set

rrevans — Mon, 01 Apr 2013 20:25:33 GMT

I have a fairly large data set of roughly 350,000 medical record numbers that were sent from a hospital database in the format of "X-#########" where x is the initial of the hospital and the digits are the actual MRN numbers. How do i completely eliminate the initial and hyphen for each observation in that column, leaving only the MRN?

e.g. H-364803055 --> 364803055

Thank You

Re: Conversion of MRN numbers in a data set

DBailey — Mon, 01 Apr 2013 20:46:30 GMT

data have;

length full_mrn $20;

input full_mrn $;

datalines;

H-364803055

run;

/*if you want character*/

data want;

set have;

mrn=substr(full_mrn,indexc(full_mrn,"-")+1);

run;

/*if you want numeric*/

data want2;

set have;

mrn=input(substr(full_mrn,indexc(full_mrn,"-")+1),20.);

run;

Re: Conversion of MRN numbers in a data set

Haikuo — Mon, 01 Apr 2013 21:01:47 GMT

There are many ways to get what you want, following are just a few examples:

data test;

var='H-364803055';

var1=compress(var,,'kd');

var2=substr(var,3);

var3=scan(var,2);

var4=prxchange("s/^.*-(\d+)/$1/o",-1,var);

run;

Haikuo

Re: Conversion of MRN numbers in a data set

Patrick — Tue, 02 Apr 2013 02:04:54 GMT

@Hai.kuo

If this is only about replacing characters then why formulate a RegEx for the whole string with a capture buffer instead of simply formulate a RegEx for the stuff you don't want and then replace it with a NULL string? ...Being a bit on a mission here because I've seen PGStats doing the same as well.

var5=prxchange("s/[^\d]//o",-1,var);

Re: Conversion of MRN numbers in a data set

rrevans — Tue, 02 Apr 2013 16:23:46 GMT

Thank you, this works:

data want2;

set have;

mrn=input(substr(mrn, indexc(mrn, "-") +1), 20.);

run;

One issue though, var does not convert to numeric. I get this kind of note:

NOTE: Numeric values have been converted to character values at the places given by:

(LINE):(COLUMN).

224:19

Any quick fix? I am going to be concatenating this list with another where the mrn is numeric.

Re: Conversion of MRN numbers in a data set

Haikuo — Tue, 02 Apr 2013 16:34:19 GMT

Good Point, Patrick. Can't speak for PG, but for me is nothing more than a habit. Always good to have another way to think.

Haikuo

Re: Conversion of MRN numbers in a data set

DBailey — Tue, 02 Apr 2013 16:36:11 GMT

You can't redefine mrn. Create a different variable to hold the numeric value:

mrn_num=input(substr(mrn, indexc(mrn, "-") +1), 20.);

Re: Conversion of MRN numbers in a data set

SandyH — Tue, 09 Apr 2013 00:59:38 GMT

Why not scan(mm,1,'-')?