topic Re: create a new variable with combinations in SAS Programming

create a new variable with combinations

lalohg — Mon, 08 Jun 2020 17:40:34 GMT

Hello there,

I have a variable with combination of colors

ID variable_combination

1 "blue, yellow, red"

2 "white, grey"

and would like to get new indicator variables for each combination so I will get:

ID variable_combination blue_yellow_red white_grey

1 "blue, yellow, red" 1 0

2 "white, grey" 0 1

all your help will be appreciated

Thanks

Lalohg

Re: create a new variable with combinations

PaigeMiller — Mon, 08 Jun 2020 17:52:15 GMT

It's hard to imagine a use for such a thing. It is not hard to image how this method will fail since SAS variable names can not exceed 32 characters.

Why do you want this? Perhaps we can find better approaches.

Re: create a new variable with combinations

Reeza — Mon, 08 Jun 2020 17:52:35 GMT

Can you provide some more records so we understand how this might scale? How many different combinations will you have? Do you know them all ahead of time?

Why do you need to make dummy variables? Most SAS Procs will do that for you these days.

Re: create a new variable with combinations

Ksharp — Tue, 09 Jun 2020 11:57:57 GMT

data have;
input ID   variable_combination	$40.;
cards;
1     "blue, yellow, red"
2     "white, grey"
;
data temp;
 set have;
 length _ $ 40;
 do i=1 to countw(variable_combination,,'ka');
  _=catx('_',_,scan(variable_combination,i,,'ka'));
 end;
 y=1;
run;
proc logistic data=temp outdesign=design(drop=y) outdesignonly;
class _ / param=glm ;
model y=_/nofit noint;
run;
data want;
 merge have design;
run;

Re: create a new variable with combinations

Ksharp — Tue, 09 Jun 2020 12:06:40 GMT

data have;
input ID   variable_combination	$40.;
v=1;
cards;
1     "blue, yellow, red"
2     "white, grey"
;
proc transpose data=have out=temp;
by id  variable_combination;
var v;
id  variable_combination;
run;
proc stdize data=temp out=want reponly missing=0;
run;

Re: create a new variable with combinations

lalohg — Tue, 09 Jun 2020 19:05:18 GMT

Hi Ksharp,

the code worked just fine!!!!

Thank you

have a nice day

Lalohg

Re: create a new variable with combinations

lalohg — Tue, 09 Jun 2020 19:07:47 GMT

this code also worked just fine!!

Thanks again