topic convert 28-APR-20 02.56.42.897749 PM ( length is 28 char ) to DATETIME in SAS Programming

convert 28-APR-20 02.56.42.897749 PM ( length is 28 char ) to DATETIME

dennis_oz — Wed, 03 Jun 2020 06:51:30 GMT

Hi all , How to convert 28-APR-20 02.56.42.897749 PM ( length is 28 char) to DATETIME ?

Please can you help.

Re: convert 28-APR-20 02.56.42.897749 PM ( length is 28 char ) to DATETIME

Kurt_Bremser — Wed, 03 Jun 2020 07:05:35 GMT

See

data want;
string = "28-APR-20 02.56.42.897749 PM";
date = input(scan(string,1," "),date9.);
time = input(substr(string,11),time20.);
datetime = dhms(date,0,0,time);
format
  date yymmddd10.
  time time15.6
  datetime e8601dt26.6
;
run;

Re: convert 28-APR-20 02.56.42.897749 PM ( length is 28 char ) to DATETIME

s_lassen — Wed, 03 Jun 2020 07:43:17 GMT

You can also wrap up the solution by @Kurt_Bremser in a macro function:

%macro dt_AMPM(str);
  %local time date;
  %let date=input(&str,date9.);
  %let time=input(substr(&str,11,time20.);
dhms(&date,0,0,&time)
%mend;

This function can then be used in a data step:

data want;
  set have;
  datetime=%dt_AMPM(date_str);
  format datetime datetime25.6;
run;

Which may be a nice solution if you have more than one datetime string in this format.

Re: convert 28-APR-20 02.56.42.897749 PM ( length is 28 char ) to DATETIME

ed_sas_member — Wed, 03 Jun 2020 07:49:11 GMT

Hi @dennis_oz

You can try informat datetime30.6 to keep the highest precision:

data want;
	string = "28-APR-20 02.56.42.897749 PM";
	string_n = input(string, DATETIME30.6);
	format string_n e8601dt26.6;
run;

Best,