topic Re: How to extract a numeric value from character variable in SAS Programming

How to extract a numeric value from character variable

knveraraju91 — Tue, 02 Jun 2020 21:42:02 GMT

Dear

I need to extract numeric value from the data below. Please suggest. Thank you

output needed;

data one;
input a $1-13;
datalines;
1
1+
2
2+
10
4
4+
normal
50
abnormal
many negative
5<
;

Re: How to extract a numeric value from character variable

Reeza — Tue, 02 Jun 2020 22:01:16 GMT

COMPRESS() with the 'kd' option to keep digits.

data want;
set have;

want = input(compress(variable, , 'kd'), 8.);

run;

@knveraraju91 wrote:

Dear

I need to extract numeric value from the data below. Please suggest. Thank you

output needed;

1

1

2

2

4

4

5

10

50
data one;
input a $1-13;
datalines;
1
1+
2
2+
10
4
4+
normal
50
abnormal
many negative
5<
;

Re: How to extract a numeric value from character variable

Jagadishkatam — Wed, 03 Jun 2020 03:51:45 GMT

Alternatively, you can use perl regular expressions as below

data one;
input a $1-13;
datalines;
1
1+
2
2+
10
4
4+
normal
50
abnormal
many negative
5<
;


data want;
set one;
want=prxchange('s/\D//oi',-1,a);
if want ne '';
run;

Re: How to extract a numeric value from character variable

s_lassen — Wed, 03 Jun 2020 05:33:13 GMT

I would use the COMPRESS function to get rid of the "<", and then use the TRAILSGN (trailing sign) informat:

data want;
  set one;
  n=input(compress(a,"<"),?? trailsgn.);
  if not missing(n);
run;

The "??" suppresses log warnings about invalid values.

Re: How to extract a numeric value from character variable

Patrick — Wed, 03 Jun 2020 07:32:28 GMT

Here a way using an Informat with a Regular Expression. I've also included the values with no digits in it in case you also want to convert these to some number. If not then simply remove these values from the informat and add a selection to your data step like:
if missing(want_var) then delete;

proc format;
  invalue toDigits(default=20 upcase) 
    'NORMAL'        = 100
    'ABNORMAL'      = 101
    'MANY NEGATIVE' = 102
    's/\D*(\d+)\D*/$1/' (regexpe) = _same_ 
    other=_same_
    ;
run;

/* use the informat to directly read the data (want_var1)
   or to convert a string from another variable (want_var2)
*/
data sample;
  input have_var $1-13 @1 want_var1 toDigits.;
  want_var2=input(have_var,toDigits.);
  datalines;
1
1+
2
2+
10
4
4+
normal
50
abnormal
many negative
5<
;

proc print;
run;