topic delete all data sets in work library except of one data set in SAS Programming

delete all data sets in work library except of one data set

Ronein — Mon, 01 Jun 2020 05:55:49 GMT

Hello

Let's say that I have many data sets in work library (let's say 2000 data sets).

I want to keep only one data set called tbl_aaa and delete all other data sets.

What is the way to tell SAS to delete all data sets in work library except of tbl_aaa?

Re: delete all data sets in work library except of one data set

Kurt_Bremser — Mon, 01 Jun 2020 06:13:23 GMT

Copy the dataset to a different library (or create it there in the first place), and use proc datasets with the kill option on WORK.

Or do this:

proc sql noprint;
select cats('WORK.',memname) into :to_delete separated by ' '
from dictionary.tables
where libname = 'WORK' and memname ne 'TBL_AAA':
quit;

proc delete data=&to_delete.;
run;

Re: delete all data sets in work library except of one data set

Jagadishkatam — Mon, 01 Jun 2020 06:21:30 GMT

Alternatively you can use the proc datasets as below, but you need the macro variable to_delete from @Kurt_Bremser code and use it in proc datasets

proc datasets lib=work memtype=data;
delete &to_delete;
run;
quit;

Re: delete all data sets in work library except of one data set

yabwon — Mon, 01 Jun 2020 06:38:39 GMT

Yet another (just for fun?) approach would be "building a shelter" 😉

data a b c d e f;
  set sashelp.class;
run;

options dlcreatedir;
libname shelter "%sysfunc(pathname(WORK))/shelter";

data shelter.a;
  set a;
run;

/*
proc datasets kill lib=work noprint;
run;
*/

proc delete lib = work data = _all_;
run;

data a;
  set shelter.a;
run;

All the best

Bart

Re: delete all data sets in work library except of one data set

Ksharp — Mon, 01 Jun 2020 11:06:32 GMT

Use SAVE statement in PROC DATASETS .

proc datasets lib=work memtype=data nodetails ;
save tbl_aaa ;
quit;