topic Re: Divide row numbers of two data sets? in SAS Programming

Divide row numbers of two data sets?

YangM90 — Thu, 14 May 2020 12:42:21 GMT

If I have two data sets, lets say:

data A;
input ColA;
datalines;
1
2
3
;
run;

data B;
input ColB;
datalines;
1
2
;
run;

Then data set A has 3 rows, while data set B has 2 rows.

I want to create a new data set, containing one element, which is x = the number of rows of A / the number of rows of B.

How can I do that? 🙂

Best regards,

Re: Divide row numbers of two data sets?

Kurt_Bremser — Thu, 14 May 2020 12:52:23 GMT

See this example:

data a;
set sashelp.class (obs=3);
run;

data b;
set sashelp.class;
run;

data want;
if nobsb ne 0 then x = nobsa / nobsb;
output;
stop;
set a nobs=nobsa;
set b nobs=nobsb;
run;

Re: Divide row numbers of two data sets?

PaigeMiller — Thu, 14 May 2020 13:00:24 GMT

Hello, @YangM90 , I am curious if this is a reasonable example. Are the data sets A and B simply integers that correspond to the row number (value of ColA is 1 in the first row and 2 in the second row and so on)? This seems unrealistic, and could perhaps result in unrealistic answers. Could you please clarify?

Re: Divide row numbers of two data sets?

ed_sas_member — Thu, 14 May 2020 14:23:19 GMT

Hi @YangM90

Here is an approach using PROC SQL and the dictionary tables, which contains metadata about SAS datasets.

proc sql;
	select case when b.nobs ne 0 then a.nobs / b.nobs else . end as ratio format=8.2
	from
		(select nobs
		 from dictionary.tables
		 where libname="WORK" and upcase(memname) = "A") as a,
		(select nobs
		 from dictionary.tables
		 where libname="WORK" and upcase(memname) = "B") as b;
run;

Best,

Re: Divide row numbers of two data sets?

YangM90 — Thu, 14 May 2020 14:27:35 GMT

Hi Kurt,

thank you!

Re: Divide row numbers of two data sets?

YangM90 — Thu, 14 May 2020 14:28:34 GMT

Hi Paige!

The data sets are not intergers / row numbers, but arbitrary real numbers.

Re: Divide row numbers of two data sets?

YangM90 — Thu, 14 May 2020 14:28:56 GMT

Hi,

thanks alot! 🙂

Re: Divide row numbers of two data sets?

ed_sas_member — Thu, 14 May 2020 14:29:27 GMT

You're welcome 🙂