topic Re: Using Command Prompt Syntax with Spaces in SAS Programming

Using Command Prompt Syntax with Spaces

djbateman — Wed, 06 May 2020 21:09:13 GMT

I am trying to get a list of files in a specified directory, but I have noticed that when using the command prompt syntax that I cannot use directories that contain a space. Does anyone know of a way to get my code to work with spaces? The code should return about 300 files, but I'm getting 0.

%let dir=S:\cdm\Programming\445\106\Data Cleaning\MDR\MDR Standard Checks\Part B\AE;
%let ext=xlsx;

filename EXTlist pipe "dir /b /s &dir.\*.&ext.";

data directory;
	infile EXTlist truncover;
	input directory $200.;
run;

Re: Using Command Prompt Syntax with Spaces

SASKiwi — Wed, 06 May 2020 21:44:51 GMT

My understanding is you need quotes around paths that include spaces. How about this?

%let dir=%str(%')S:\cdm\Programming\445\106\Data Cleaning\MDR\MDR Standard Checks\Part B\AE;
%let ext=xlsx%str(%');

Re: Using Command Prompt Syntax with Spaces

ChrisNZ — Wed, 06 May 2020 22:06:45 GMT

Better in my opinion to leave the macro variable unquoted, and quote when used.

%let dir=S:\cdm\Programming\445\106\Data Cleaning\MDR\MDR Standard Checks\Part B\AE;
%let ext=xlsx;

filename EXTlist pipe "dir /b /s ""&dir.\*.&ext"" ";

data directory;
	infile EXTlist truncover;
	input directory $200.;
run;

Re: Using Command Prompt Syntax with Spaces

RichardDeVen — Wed, 06 May 2020 23:29:16 GMT

Windows filenames can contain ampersands. You will want to be sure SAS does not try to use the & as a resolution directive.

Example:

Wrap path in %NRSTR for explicit assignment. Use %SUPERQ to resolve the symbol only.

%let path = %nrstr(c:\temp\tom&jerry videos);

filename dir pipe "dir /b /s ""%superq(path)""";

data _null_;
  infile dir;
  input;
  put _infile_;
run;

Re: Using Command Prompt Syntax with Spaces

djbateman — Thu, 07 May 2020 13:18:08 GMT

I knew it was some kind of quoting issue, but I couldn't figure out how many quotes to use, and if they should be single or double. This method did the trick. Thanks!