topic need the logic to tell if this value looks like numeric in SAS Programming

need the logic to tell if this value looks like numeric

ZRick — Tue, 24 Sep 2013 00:53:42 GMT

I need to convert some of the following values into numberic when it looks like a numberic, based on its appearances.

How can I develop this logic?

data tmp;

length value $ 4;

input value;

cards;

1234

sys

;;

run;

Re: need the logic to tell if this value looks like numeric

Miracle — Tue, 24 Sep 2013 01:52:07 GMT

Hi ZRick. I wonder if this helps.

data tmp;

length value $ 4;

input value;

cards;

1234

sys

;;

run;

data flag; set tmp; flag=ifc(anyalpha(value),'string','numeric'); run;

proc print noobs;; run;

Re: need the logic to tell if this value looks like numeric

Patrick — Tue, 24 Sep 2013 02:42:07 GMT

You could use something like:

data tmp;

length string $ 4;

input string;

number=input(string,?? best.);

cards;

1234

sys

;;

run;

This will convert the string to a numeric value if possible - else number will contain a missing;

Re: need the logic to tell if this value looks like numeric

yaswanthj — Wed, 25 Sep 2013 10:02:12 GMT

Hi..

If you want to create new flags as string and numeric.

data tmp;

length value $ 4;

input value;

cards;

1234

sys

;;

run;

data flag;

set tmp;

string1 = anyalpha(value);

if string1 = 1 then string = value;else number=value; * then string = value;*else value = numeric;

drop string1;

/*put value= flag=;*/

run;

proc print noobs;; run;

Thanks,

Yash

Re: need the logic to tell if this value looks like numeric

data_null__ — Wed, 25 Sep 2013 10:19:34 GMT

K C Wong wrote:

Hi ZRick. I wonder if this helps.

data tmp;
length value $ 4;
input value;
cards;
1234
sys
;;
run;
data flag; set tmp; flag=ifc(anyalpha(value),'string','numeric'); run;
proc print noobs;; run;

You got close but what about E and D for example "1e6"

data tmp;
   input value $;
   a = input(value,comma8.);
   length flag $8; 
   flag=ifc(anyalpha(value),'string?','numeric?'); 
   cards; 
1234
-1234
+1234
1.3
1e-3
3d2
4,000
-4,000.9
sys
;;;;
   run; 
proc print; 
   run; 

Re: need the logic to tell if this value looks like numeric

Miracle — Mon, 30 Sep 2013 02:11:17 GMT

Unless ZRick's data has such cases ie 1e6 which I dunno about

Re: need the logic to tell if this value looks like numeric

data_null__ — Mon, 30 Sep 2013 11:34:52 GMT

Yes you don't know.

Re: need the logic to tell if this value looks like numeric

PGStats — Mon, 30 Sep 2013 14:56:59 GMT

Building on DN and Patrick's input :

data tmp;
   length value flag $8;
   input value $&;
   a = input(value,?? comma8.);
   format a best8.;
   flag=ifc(missing(a), 'string', 'numeric');
datalines;
1234
-1234
+1234
1.3
1e-3
3d2
4,000
-4,000.9
sys
;

proc print data=tmp noobs; run;