topic Re: How to create a variable to subgroup observations within a group in SAS Programming

How to create a variable to subgroup observations within a group

xyxu — Mon, 27 Apr 2020 05:50:45 GMT

I have a dataset that has multiple groups of observations. There is a variable, flag, which either takes value 1 or missing. I want to create a new variable to divide each group into subgroups based on the value of flag. Whenever flag = 1, start counting a new subgroup. Please see the code below as an example.

data have;
	input group flag;
	datalines;
101 .
101 .
101 1
101 .
101 1
101 .
101 .
102 .
102 1
102 .
102 .
;

data want;
	input group flag new_var;
	datalines;
101 . 1
101 . 1
101 1 2
101 . 2
101 1 3
101 . 3
101 . 3
102 . 1
102 1 2
102 . 2
102 . 2
;

Re: How to create a variable to subgroup observations within a group

Jagadishkatam — Mon, 27 Apr 2020 06:19:45 GMT

please try the below code for flag2

data have;
	input group flag;
	datalines;
101 .
101 .
101 1
101 .
101 1
101 .
101 .
102 .
102 1
102 .
102 .
;

data want;
set have;
by group flag notsorted;
retain new_var;
if first.group then new_var=1;
else new_var+flag;
run;

Re: How to create a variable to subgroup observations within a group

Kurt_Bremser — Mon, 27 Apr 2020 06:11:32 GMT

data want;
set have;
by group;
if first.group
then newvar = 1;
else if flag then newvar + 1;
run;

Re: How to create a variable to subgroup observations within a group

andreas_lds — Mon, 27 Apr 2020 07:07:47 GMT

If you want a more arcane solution, try:

data want;
	set have;
	by group;
	length new_var 8;
	retain new_var;
		
	new_var = ifn(first.group, 1, new_var) + sum(0, flag);
run;