topic How to create new dataset with daily dates for each state? in SAS Programming

How to create new dataset with daily dates for each state?

wernie — Thu, 23 Apr 2020 13:31:12 GMT

I am starting from scratch and want to create a dataset that has daily dates (e.g., starting 03/15/2020 through something that would be today's date whenever it is run) for each state (see below for example). I'll then use that as my base to fill in my other conditional variables. How can I do this?

Date State

03/15/2020 AK

03/15/2020 AL

............. ....

03/15/2020 WY

03/16/2020 AK

03/16/2020 AL

and so on through 04/23/2020 (or whatever the current date is for the day it is being run)

Thanks!

Re: How to create new dataset with daily dates for each state?

PaigeMiller — Thu, 23 Apr 2020 13:36:21 GMT

data want;
     t=today();
     do date='15MAR20'd to t by 1;
        do state='AL','AK'; /* you type the rest, I'm lazy */
             output;
         end;
     end; 
     format date yymmdd.;
     drop t;
run;

Re: How to create new dataset with daily dates for each state?

Patrick — Thu, 23 Apr 2020 13:56:23 GMT

or if you've already got a table with the states:

proc sql;
  create table have_states as
    select distinct MapIdName as State
    from sashelp.gcstate
    where isoalpha3='USA'
    ;
quit;

data want;
  set have_states;
  format dt date9.;
  do dt='15Mar2020'd to today();
    output;
  end;
run;

proc print data=want(obs=5);
run;

Re: How to create new dataset with daily dates for each state?

ballardw — Thu, 23 Apr 2020 14:02:24 GMT

Do your states have to include the US protectorates like Puerto Rico or Virgin Islands?