topic Re: using index to clean string variable in SAS Programming

using index to clean string variable

Cruise — Sun, 19 Apr 2020 17:56:13 GMT

Hi Folks:

I'm trying to use the beginning part of the string variable (i.e., Albany- or Albany(county) or Albany county) until any of these symbols happen as part of the string: '-', ' ' , '('

The code below does the job but too inefficient.

Is there a way to accomplish this in a single step?

data TEMP; set census_age1; 
IDNAME1=substr(IDNAME,1,index(IDNAME,'-')-1);
DROP IDNAME; RENAME IDNAME1=IDNAME;   
ID1NAME1=substr(ID1NAME,1,index(ID1NAME,'-')-1);
DROP ID1NAME; RENAME ID1NAME1=ID1NAME; 
RUN;
DATA TEMP1; SET TEMP; 
IDNAME1=substr(IDNAME,1,index(IDNAME,' ')-1);
DROP IDNAME; RENAME IDNAME1=IDNAME;  
RUN;
DATA census_age2; SET TEMP1; 
IDNAME1=substr(IDNAME,1,index(IDNAME,'(')-1);
DROP IDNAME; RENAME IDNAME1=IDNAME; 
run;

Re: using index to clean string variable

PaigeMiller — Sun, 19 Apr 2020 18:10:41 GMT

@Cruise wrote:

Hi Folks:

I'm trying to use the beginning part of the string variable (i.e., Albany- or Albany(county) or Albany county) until any of these symbols happen as part of the string: '-', ' ' , '('

The code below does the job but too inefficient.

Is there a way to accomplish this in a single step?

You don't say what the desired output is. You don't provide (a portion of) the input data set. We need those things if we're going to help you.

Re: using index to clean string variable

unison — Sun, 19 Apr 2020 18:39:34 GMT

You can try scan:

data have;
	input idname $20.;
	datalines;
Albany-
Albany(county)
Albany (county)
Albany
;
run;

data want(rename=new_idname=idname);
	set have;
	new_idname=scan(idname, 1, '(- ');
	drop idname;
run;

Re: using index to clean string variable

Cruise — Sun, 19 Apr 2020 18:42:42 GMT

Thanks, solved the problem. Sorry for not providing a mock data. Thanks again!