topic Re: How To: Change the symbol/sings in scatter plot that grouped by class in SAS Programming

How To: Change the symbol/sings in scatter plot that grouped by class

learn001 — Sun, 12 Apr 2020 01:27:20 GMT

I'm trying to plot two variables and by using different colors/signs to plot the points belonging to three different classes.

Code :

ods graphics / reset width=6.4in height=4.8in imagemap;

proc sgplot data=WORK.FINALWINEDATA;
scatter x=Alcohol y=Total_phenols / group=Class
markerattrs=(symbol=circlefilled size=10);
xaxis grid;
yaxis grid;
run;

ods graphics / reset;

But when i'm trying add more symbol, i get below error message

1 OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;

NOTE: ODS statements in the SAS Studio environment may disable some output features.

75 /* Plot the graph*/

76 ods graphics / reset width=6.4in height=4.8in imagemap;

78 proc sgplot data=WORK.FINALWINEDATA;

79 scatter x=Alcohol y=Total_phenols / group=Class

80 markerattrs=(symbol=circlefilled trianglefilled diamondfilled size=10);

______________

202

ERROR 22-322: Syntax error, expecting one of the following: ), COLOR, SIZE, SYMBOL.

ERROR 202-322: The option or parameter is not recognized and will be ignored.

81 xaxis grid;

82 yaxis grid;

83 run;

NOTE: The SAS System stopped processing this step because of errors.

NOTE: PROCEDURE SGPLOT used (Total process time):

real time 0.00 seconds

cpu time 0.00 seconds

85 ods graphics / reset;

87 OPTIONS NONOTES NOSTIMER NOSOURCE NOSYNTAXCHECK;

Re: How To: Change the symbol/sings in scatter plot that grouped by class

RichardDeVen — Sun, 12 Apr 2020 06:31:05 GMT

The STYLEATTRS statement will override default color and style cycling.

Blog entry "Attrs, attrs, everywhere: The interaction between ATTRPRIORITY, CYCLEATTRS, and STYLEATTRS in ODS graphics" covers the topic in more detail.

data have; do x = 0 to 20 by .25; class = 'A'; y = sin(x+5); output; class = 'B'; y = 2 + 2 * sin(x/2); output; class = 'C'; y = 6 + 3 * sin(x/1.25); output; end; run; ods html file='series.html'; ods graphics / attrpriority=none; proc sgplot data=have; scatter x=x y=y / group=class ; styleattrs datacontrastcolors = ( black red purple ) datasymbols = ( circlefilled trianglefilled diamondfilled ) ; run; ods html close;

Re: How To: Change the symbol/sings in scatter plot that grouped by class

learn001 — Wed, 15 Apr 2020 20:52:09 GMT

Issue Resolved!

I used below refer code to fix my issue.

ods graphics on / attrpriority=color;
proc sgplot data=sashelp.iris aspect=1;
   scatter x=petalwidth y=sepalwidth / group=species;
   keylegend / location=outside position=right across=1;
run;

ods graphics on / attrpriority=none;
proc sgplot data=sashelp.iris aspect=1;
   styleattrs datasymbols=(trianglefilled circlefilled squarefilled);
   scatter x=petalwidth y=sepalwidth / group=species;
   keylegend / location=outside position=right across=1;
run;

Reference Link : https://blogs.sas.com/content/graphicallyspeaking/2018/10/08/getting-started-with-sgplot-part-13-style-attributes/#prettyPhoto

Regards

Lokesh