topic Re: Mod function in SAS Programming

Mod function

PurushReddy — Tue, 14 Apr 2020 08:09:42 GMT

I want prime numbers from 1 to 1000
Please explain the logic with using mod function

Re: Mod function

PeterClemmensen — Tue, 14 Apr 2020 08:43:28 GMT

What have you tried so far? The community has many many examples of code that does this already 🙂

Re: Mod function

Kurt_Bremser — Tue, 14 Apr 2020 10:31:51 GMT

You don't need the mod() function, you use the simple elimination method:

data primes;
array primes {1000} _temporary_ (1000*1);
do i = 2 to 1000;
  if primes{i} then do j = 2 * i to 1000 by i;
    primes{j} = 0;
  end;
end;
do number = 2 to 1000;
  if primes{number} then output;
end;
keep number;
run;

Re: Mod function

yabwon — Tue, 14 Apr 2020 10:28:46 GMT

With 1 small modification:

do number = 2 to 1000;
if primes{number} then output;
end;

All the best
Bart

Re: Mod function

Kurt_Bremser — Tue, 14 Apr 2020 10:32:21 GMT

Done.

Re: Mod function

Ksharp — Tue, 14 Apr 2020 11:13:55 GMT

Kurt,
To make it faster, code could change it into

do i = 2 to int(sqrt(1000));

Re: Mod function

Kurt_Bremser — Tue, 14 Apr 2020 12:25:58 GMT

Revised code, made dynamic and optimized:

%let max=1000000;

data primes;
array primes {&max.} _temporary_ (&max.*1);
do i = 2 to int(sqrt(&max.));
  if primes{i} then do j = 2 * i to &max. by i;
    primes{j} = 0;
  end;
end;
do number = 2 to &max.;
  if primes{number} then output;
end;
keep number;
run;

I used a million because before that, there was no measurable difference between with and without the sqrt function. With a million, the difference was .06 seconds to .10 seconds in favor of using the function, using UE on a MacBook Pro.

Re: Mod function

yabwon — Tue, 14 Apr 2020 12:28:50 GMT

@Kurt_Bremser

Kurt,

If you make it:

  array primes {&max.} _temporary_;
  do number = 1 to &max.;
    primes{number} = 1;
  end;

you will reduce memory by 50%.

All the best

Bart

Re: Mod function

Kurt_Bremser — Tue, 14 Apr 2020 12:41:13 GMT

There seems to be slight tradeoff (the additional do loop added another .01 seconds), but this is a valid point when &max is increased by several orders of magnitude.