topic Re: Retain value based on the condition per ID in SAS Programming

Retain value based on the condition per ID

Dinurik — Fri, 03 Apr 2020 20:14:51 GMT

Hi SAS programmers,

Could you please help me with the following problem?

My data is:

data have;

input id visit cvd;

datalines;

1 1 0

1 3 0

1 5 1

1 9 0

2 3 .

2 4 1

2 5 0

2 9 .

;

If a subject had cardiovascular even (CVD=1), I need them to retain CVD=1 in all subsequent visits. Data are unbalanced, measurements are taken for participants at different visits, and there are missing values. So I need to preserve missingness and zeros, unless subjects hits CVD=1, then “1” needs to be carried on until the last visit per id.

Any help/tips will be highly appreciated!

Re: Retain value based on the condition per ID

ballardw — Fri, 03 Apr 2020 20:28:46 GMT

Here is one way for the given data.

 data have;
    input id visit cvd;
datalines;
1   1    0
1   3    0
1   5    1
1   9    0
2   3    .
2  4    1
2  5    0
2   9    .
;


data want;
   set have;
   by id;
   retain cvdtru;
   /* reset the retained value for the first visit
      of each id
   */
   if first.id then call missing(cvdtru);
   /* when find the cvd=1 then set the retained value*/
   if cvd=1 then cvdtru=1;
   /* if the retained value is set, then assign
      it to the needed variable
   */
   if cvdtru=1 then cvd=1;
   drop cvdtru;
run;

assume the data are sorted by ID and visit number as shown.

Re: Retain value based on the condition per ID

Dinurik — Fri, 03 Apr 2020 20:44:14 GMT

Thank you so much! It worked.