topic Re: Using a Wildcard in Filename Statement in SAS Programming

Using a Wildcard in Filename Statement

buechler66 — Mon, 30 Mar 2020 15:29:19 GMT

Hi. I have a Filename Statement that I need to use a wildcard in (e.g. *). The first commented out Filename Statement works fine, but when I update the code to use the uncommented Filename Statement which includes the * wildcard the code errors out.

Any suggestions on how I can correct this issue? I'd appreciate any help. Thanks.

/*FILENAME Site "'C:\Users\SteveBuechler\Box Sync\IBM\USPS\In Scope Contracts For Site\Parsed Output_Erie 0330_1000.xlsx'";*/

FILENAME Site "'C:\Users\SteveBuechler\Box Sync\IBM\USPS\In Scope Contracts For Site\Parsed Output_Erie*.xlsx'";

PROC IMPORT OUT= Sites&site DATAFILE= Site
            DBMS=XLSX REPLACE;
     SHEET="Trips";
     GETNAMES=YES;
RUN;

ERROR: Physical file does not exist, C:\\U.
NOTE: The SAS System stopped processing this step because of errors.
NOTE: PROCEDURE IMPORT used (Total process time):
      real time           0.02 seconds
      cpu time            0.03 seconds

Re: Using a Wildcard in Filename Statement

buechler66 — Mon, 30 Mar 2020 15:32:20 GMT

Note that using the wildcard I will be defining the same file, just without the Date Time portion of the name. Only one file will ever qualify even tho I'm using the * wildcard.

Re: Using a Wildcard in Filename Statement

novinosrin — Mon, 30 Mar 2020 15:37:17 GMT

HI @buechler66 May I ask the reason you are having quotes within quotes?

Though I don't think that causes errors, but just asking. I would have thought the syntax is rather convenient to have

FILENAME Site "C:\Users\SteveBuechler\Box Sync\IBM\USPS\In Scope Contracts For Site\Parsed Output_Erie*.xlsx";

Re: Using a Wildcard in Filename Statement

buechler66 — Mon, 30 Mar 2020 15:41:19 GMT

No reason, I've just been trying various syntax to see if I can get the *
wildcard to work.

Re: Using a Wildcard in Filename Statement

Tom — Mon, 30 Mar 2020 15:51:47 GMT

Perhaps it is just that PROC IMPORT doesn't get it.

Try finding the filename yourself first.

data _null_;
  length fname $256 ;
  infile "C:\Users\SteveBuechler\Box Sync\IBM\USPS\In Scope Contracts For Site\Parsed Output_Erie*.xlsx"
          obs=1 filename=fname
  ;
  input;
  call symputx('fname',fname);
run;

PROC IMPORT OUT= Sites&site DATAFILE= "&fname"
            DBMS=XLSX REPLACE
;
     SHEET="Trips";
     GETNAMES=YES;
RUN;

Re: Using a Wildcard in Filename Statement

ballardw — Mon, 30 Mar 2020 16:02:46 GMT

Is this a complete example? Typically you would not use a mix of double and single quotes in a filename as shown for a single input file.

And if your wildcard expansion results in two or more files then Proc Import isn't going to like it.

Re: Using a Wildcard in Filename Statement

buechler66 — Mon, 30 Mar 2020 19:05:10 GMT

Works like a charms. Thanks for taking the time to help!