topic Re: Insert space between Char and Numeric in SAS Programming

Insert space between Char and Numeric

Krauss — Thu, 19 Mar 2020 16:33:58 GMT

Hello,

At first sight, it could seems to be an easy question, but i can't solve it.

In a string I could have something like this:

Have: street flowers4 nowhere want: street flowers 4 nowhere

Have: 4Avenue10 nowhere want: 4 Avenue 10 nowhere

Resuming, insert a space when there's a sequence char/numeric or numeric/char.

How can I do this if don't know the position where it may occur?

Thanks in advance!

Re: Insert space between Char and Numeric

FreelanceReinh — Thu, 19 Mar 2020 17:18:06 GMT

Hello @Krauss,

Maybe it's easier to handle the two cases separately, e.g. like this:

data have;
input c $50.;
cards;
street flowers4 nowhere
4Avenue10 nowhere
;

data want;
set have;
c=prxchange('s/([^\d\s])(\d)/$1 $2/', -1, c);
c=prxchange('s/(\d)([^\d\s])/$1 $2/', -1, c);
run;

The regular expression [^\d\s] means "not a digit or whitespace character." You may want to change it to something else, for example to [[:alpha:]] if your definition of "Char" does not include punctuation marks, but only alphabetic characters.

Re: Insert space between Char and Numeric

PGStats — Thu, 19 Mar 2020 17:34:34 GMT

Use regular expressions:

data have;
informat line $64.;
input line &;
datalines;
street flowers4 nowhere
4Avenue10 nowhere
;
 
data want;
set have;
length newLine $128;
newLine = compbl(prxChange("s/(\d+)/ \1 /o", -1, line));
run;

proc print; run;

Re: Insert space between Char and Numeric

Krauss — Thu, 19 Mar 2020 17:54:38 GMT

That's exactly what I asked for!

Thank you!

Re: Insert space between Char and Numeric

Krauss — Thu, 19 Mar 2020 17:55:14 GMT

Thank you for your answer.

Re: Insert space between Char and Numeric

FreelanceReinh — Thu, 19 Mar 2020 20:37:14 GMT

@Krauss wrote:

That's exactly what I asked for!

Not exactly, I'd say: For example, your second test string gets indented by one character because a blank is inserted left to the "4" although there was no "char" justifying this insertion ("insert a space when there's a sequence char/numeric or numeric/char"). But, of course, this is not a big issue and PG's solution is elegant (as always) in that it requires only a single assignment statement.

Re: Insert space between Char and Numeric

PGStats — Thu, 19 Mar 2020 22:57:21 GMT

Yes @FreelanceReinh , good point. I have taken liberties with OP stated requirements. But then, those might not be exactly what is really required! I guess you might want to use left(compbl(...)) if you never want leading spaces.