topic Re: separate a name by blank in SAS Programming

separate a name by blank

harrylui — Tue, 03 Mar 2020 07:38:58 GMT

good day all,

can i separate a name by blank?

for example

Name

Liverpool Virgil van Dijk

separate a name by blank into 4 columns

column1 column2 column3 column4

Liverpool Virgil van Dijk

is there any way to do it?

thanks in advance

Regards,

Harry

Re: separate a name by blank

PeterClemmensen — Tue, 03 Mar 2020 07:52:21 GMT

Sounds like a job for the CATX Function

Re: separate a name by blank

ed_sas_member — Tue, 03 Mar 2020 09:22:51 GMT

Hi @harrylui

If you want to concatenate several columns using a blank as a delimiter, you can use the CATX function as suggested by @PeterClemmensen

/* Concatenate */

data have;
	input column1:$30. column2:$30. column3:$30. column4:$30.;
	datalines;
Liverpool  Virgil van Dijk
;
run;
 
data want;
	set have;
	name = catx(" ",column1, column2, column3, column4);
run;

If you want to separate the words of a sting in as many columns, you can do this, using the COUNTW() and SCAN() function:

/* Separate */

data have;
	input name $50.;
	datalines;
Liverpool  Virgil van Dijk
;
run;

proc sql noprint;
	select max(countw(name)) into:max_count from have;
quit;

data want;
	set have;
	array column(&max_count) $ 30;
	do i=1 to countw(name);
		column(i) = scan(name,i," ");
	end;
	drop i;
run;

Best,