topic removing the special code value in SAS Programming

removing the special code value

cho16 — Mon, 10 Feb 2020 22:03:27 GMT

I have a data set with a bunch of code as example below. I want to delete the code BH1003 for all LOB’s except HAR.

Any help with SAS code is much appreciated.

Code LOB

BH1003 HAR

BH1003 LIP

BH1003,BH1005,BH1007 LIP

BH1005 MA

AEHJ IP

BH1003,BH1006,BH1008 HAR

BH1006,BH1003,BH1004 CCC

Want

Code LOB

BH1003 HAR

BH1005,BH1007 LIP

BH1005 MA

AEHJ IP

BH1003,BH1006,BH1008 HAR

BH1006, BH1004 CCC

Re: removing the special code value

novinosrin — Mon, 10 Feb 2020 22:12:13 GMT

Hi @cho16 See if this helps


data have;
input Code       :$30.                              LOB $;
cards;
BH1003                                 HAR
BH1003                                 LIP
BH1003,BH1005,BH1007   LIP
BH1005                                 MA
AEHJ                                    IP
BH1003,BH1006,BH1008   HAR
BH1006,BH1003,BH1004   CCC
;

data want;
 set have;
 length want $100;
 if lob ne 'HAR' then
 do _n_=1 to countw(code,',');
  if scan(code,_n_,',')='BH1003' then continue;
  want=catx(',',want,scan(code,_n_,','));
 end;
 else want=code;
 if want>' ';
run;

Re: removing the special code value

kiranv_ — Tue, 11 Feb 2020 00:55:27 GMT

data want;
set have;
if LOB ne 'HAR' then do;
code= tranwrd(code,'BH1003,',''  );
code= tranwrd(code,'BH1003',''  );
end;
if code = '' then delete;
run;

Re: removing the special code value

Patrick — Tue, 11 Feb 2020 01:18:42 GMT

or this way.

data have;
  input Codes :$40. LOB $;
  datalines;
BH1003 HAR
BH1003 LIP
BH1003,BH1005,BH1007 LIP
BH1005 MA
AEHJ IP
BH1003,BH1006,BH1008 HAR
BH1006,BH1003,BH1004 CCC
;

data want;
  set have;
  if lob ne 'HAR' then
    do;
      codes=prxchange('s/\bBH1003\b,?//oi',-1,strip(codes));
      if missing(codes) then delete;
    end;
run;

proc print;
run;