topic Re: How to create sas date variable (year.quarter) from character variable in SAS Programming

How to create sas date variable (year.quarter) from character variable

Geo321 — Thu, 16 Jan 2020 14:48:21 GMT

Hi,

i am trying to create a SAS-formated date variable from a Character variable that contains information about the quarter and year.

Can someone help me with this?

Data:

obs char.var_(quarter_year) SAS-format_date_QYear_variable

1 Q1_2004 ?

2 Q2_2004 ?

3 Q3_2004 ?

4 Q4_2004 ?

5 Q1_2005 ?

6 Q2_2005 ?

7 Q3_2005 ?

.. .. ..

Thanks!

Re: How to create sas date variable (year.quarter) from character variable

novinosrin — Thu, 16 Jan 2020 14:57:28 GMT

HI @Geo321 Are you asking for something like this?

data have;
input obs  charvar $;* date_QYear_variable $;
cards;
1      Q1_2004                         ? 
2      Q2_2004                         ?
3      Q3_2004                         ?
4      Q4_2004                         ?
5      Q1_2005                         ?
6      Q2_2005                         ?
7      Q3_2005                         ?
;

data want;
 set have;
 date_QYear_variable=input(cats(scan(charvar,-1,'_'),scan(charvar,1,'_')),yyq6.);
 qtr=qtr(date_QYear_variable);
 year=year(date_QYear_variable);
 format date_QYear_variable yyq6.;
run;

Re: How to create sas date variable (year.quarter) from character variable

yabwon — Thu, 16 Jan 2020 15:10:03 GMT

Hi @Geo321 ,

You could use YYQ() function

data have;
input obs  charvar $;* date_QYear_variable $;
cards;
1      Q1_2004                         ? 
2      Q2_2004                         ?
3      Q3_2004                         ?
4      Q4_2004                         ?
5      Q1_2005                         ?
6      Q2_2005                         ?
7      Q3_2005                         ?
;
run;

data want;
set have;
y = input(scan(charvar,-1,"_"),best32.); drop y;
q = input(scan(charvar,-2,"Q_"),best32.); drop q;
format date_QYear_variable yyq6.;
date_QYear_variable = YYQ(y,q); /* it will give you the beginning of a quarter*/
run;

All the best

Bart

Re: How to create sas date variable (year.quarter) from character variable

Geo321 — Thu, 16 Jan 2020 15:15:28 GMT

Thanks!

Re: How to create sas date variable (year.quarter) from character variable

Geo321 — Thu, 16 Jan 2020 15:16:56 GMT

This also works. Thanks!