topic Choosing all numeric variables exeptc one to a model. in SAS Programming

Choosing all numeric variables exeptc one to a model.

dawidkaz — Fri, 10 Jan 2020 19:12:14 GMT

Hello,

my phrege procedure seams to not work corectly since I want to include in a model all nunmeric variables from the data set while the censoring variable is also numeric.

I got the warning:

The censoring variable rc is also an explanatory variable.

ods graphics on;
proc phreg data=model_cox alpha=0.05 namelen=32;
class &zm_class. / order=freq ref=first;
model ttd * rc(0,1) = _NUMERIC_ / ties = breslow rl=wald selection=stepwise /*slentry=0.25
slstay=0.15*/;
ods graphics off;

Is there a easy way to pick all numeric variables exept for rc?

Thank you

Re: Choosing all numeric variables exeptc one to a model.

Tom — Fri, 10 Jan 2020 19:21:24 GMT

Might just be easiest to put the list into a macro variable.

proc contents data=model_cox  noprint out=contents; run;
proc sql noprint;
select name into :names separated by ' '
  from contents
  where type=1 and upcase(name) ne 'RC' 
;
quit;

proc phreg data=model_cox alpha=0.05 namelen=32;
  class &zm_class. / order=freq ref=first;
  model ttd * rc(0,1) = &names 
      / ties = breslow rl=wald selection=stepwise 
          /* slentry=0.25 slstay=0.15 */
;
run;
quit;

Re: Choosing all numeric variables exeptc one to a model.

Reeza — Fri, 10 Jan 2020 20:32:00 GMT

Here is a reference that illustrates how to refer to variables and datasets in a short cut list:
https://blogs.sas.com/content/iml/2018/05/29/6-easy-ways-to-specify-a-list-of-variables-in-sas.html

Depending on where in the data set the variable is located, this may be an option:

firstVar-numeric-lastVar;

@dawidkaz wrote:

Hello,

my phrege procedure seams to not work corectly since I want to include in a model all nunmeric variables from the data set while the censoring variable is also numeric.

I got the warning:

The censoring variable rc is also an explanatory variable.

ods graphics on;
proc phreg data=model_cox alpha=0.05 namelen=32;
class &zm_class. / order=freq ref=first;
model ttd * rc(0,1) = _NUMERIC_ / ties = breslow rl=wald selection=stepwise /*slentry=0.25
slstay=0.15*/;
ods graphics off;

Is there a easy way to pick all numeric variables exept for rc?

Thank you