topic Re: character array concatenation problem in SAS Programming

character array concatenation problem

shawn123 — Tue, 07 Jan 2020 20:22:53 GMT

data array1;
array mark{*} $ mark1-mark5;
array markplusone{*} $ mark6-mark10;
input mark1-mark5;
do i=1 to dim(mark);
markplusone(i)='a'||mark(i);/*different concatenation*/
end;
drop mark1-mark5;
cards;
a b c d e 
;run;

data array1;
array mark{*} $ mark1-mark5;
array markplusone{*} $ mark6-mark10;
input mark1-mark5;
do i=1 to dim(mark);
markplusone(i)=mark(i)||'a'; /*different concatenation*/
end;
drop mark1-mark5;
cards;
a b c d e 
;run;   /*why this concatenation is not working?*/

The picture attached below is for the second code output.

Re: character array concatenation problem

PaigeMiller — Tue, 07 Jan 2020 20:31:57 GMT

So mark1 has length 8. So the value is actually the letter 'a' follow by 7 blanks.

Mark6 also has length 8. So when you append the new letter 'a' to mark1, that would make it 9 characters and so the 9th one gets dropped because the length of mark6 is also 8.

How about this:

data array1;
array mark{*} $ mark1-mark5;
array markplusone{*} $ mark6-mark10;
input mark1-mark5;
do i=1 to dim(mark);
markplusone(i)=trim(mark(i))||'a'; /*different concatenation*/
end;
/*drop mark1-mark5;*/
cards;
a b c d e 
;run;

markplusone(i)=cats(mark(i),'a');

Re: character array concatenation problem

shawn123 — Tue, 07 Jan 2020 20:32:12 GMT

Thank you so much, Now I understand!