topic Re: Character DateTime to Date in SAS Programming

Character DateTime to Date

Eugenio211 — Thu, 12 Dec 2019 14:25:05 GMT

Hello!

Can someone help me to convert a Character datetime type variable into a Date format? thanks

example:

2014-08-24 13:20:00.0000000 -04:00

I used this data step to convert character datetime to date, however it's not giving me the result I wanted.

data want; set have;
new_date=input(date_entered,anydtdtm.);
format new_date mmddyy10.;
run;

I'm getting ********* as a result.

Re: Character DateTime to Date

Kurt_Bremser — Thu, 12 Dec 2019 14:29:03 GMT

Add the datepart() function:

data test;
date_entered = "2014-08-24 13:20:00.0000000 -04:00";
new_date = datepart(input(date_entered,anydtdtm.));
format new_date mmddyy10.;
run;

Re: Character DateTime to Date

novinosrin — Thu, 12 Dec 2019 14:35:14 GMT

HI @Eugenio211

Use yymmdd10. informat

data want; 

set have;
new_date=input(date_entered,yymmdd10.);
format new_date mmddyy10.;
run;

Re: Character DateTime to Date

Tom — Thu, 12 Dec 2019 14:36:09 GMT

Why did you use the INFORMAT (anydtDTM) that creates a datetime value if you wanted a date value?

Just change the informat to one that generates a date value.

data want; 
  set have;
  new_date=input(date_entered,anydtDTE.);
  format new_date mmddyy10.;
run;

Re: Character DateTime to Date

Eugenio211 — Thu, 12 Dec 2019 14:37:25 GMT

thanks so much, the datepart worked.

Convert Character to Numeric to Date

Eugenio211 — Thu, 19 Dec 2019 15:45:31 GMT

Hello!

I am trying to convert a character date data to numeric to date. Can someone assist? thanks.

Example Data:

2015-04-07 14:35:00.0000000 -04:00

Re: Convert Character to Numeric to Date

PaigeMiller — Thu, 19 Dec 2019 15:53:21 GMT

Didn't you ask this question a few days ago? You even marked the answer correct.

https://communities.sas.com/t5/SAS-Programming/Character-DateTime-to-Date/m-p/611322#M178165

Re: Convert Character to Numeric to Date

Tom — Thu, 19 Dec 2019 15:53:53 GMT

If you just want the DATE from that sting you can use the INPUT() function with the YYMMDD10. informat to just read the first 10 characters.

Or did you instead want to generate the DATETIME value that the string represents? If so do you really need to subtract the 4 hours that the tail end seems to indicate?

647   data x;
648    string='2015-04-07 14:35:00.0000000 -04:00';
649    date1=input(string,yymmdd10.);
650    datetime1=input(string,anydtdtm28.);
651    format date1 yymmdd10.  datetime1 datetime20. ;
652    put (_all_) (=/);
653   run;


string=2015-04-07 14:35:00.0000000 -04:00
date1=2015-04-07
datetime1=07APR2015:14:35:00

Re: Convert Character to Numeric to Date

Eugenio211 — Thu, 19 Dec 2019 15:57:33 GMT

Thank you Tom.

Re: Convert Character to Numeric to Date

Kurt_Bremser — Thu, 19 Dec 2019 20:41:23 GMT

I merged it back into the original thread, to keep all answers in one place.