topic Re: how to filter dates based on character isodate in SAS Programming

how to filter dates based on character isodate

noda6003 — Tue, 10 Dec 2019 16:09:05 GMT

I think i asked smiliar question but since a new question arised want to know how to filter on date with character date which is in "2017-02-16T14:25:10" format. i need to filter on date less than or equal to 10jan2019 based on character date.

I used the below but it didnt work

if input(chdt, is8601dt.) le 2019-01-10;

any help

Re: how to filter dates based on character isodate

novinosrin — Tue, 10 Dec 2019 16:15:58 GMT

where input(chdt, yymmdd10.)<='10JAN2019'd;

Hi @noda6003 Basically, the idea is to read the first 10 bytes of chars using the informat yymmdd10. as the pattern resembles year-month-date

Re: how to filter dates based on character isodate

ed_sas_member — Tue, 10 Dec 2019 16:31:09 GMT

Hi @noda6003

You can try this code:

data have;
	input datec $19.;
	cards;
2017-02-16T14:25:10
;
run;

data want;
	set have;
	if datepart(input(datec,is8601dt.)) le '10JAN2019'd;
run;

Re: how to filter dates based on character isodate

Tom — Tue, 10 Dec 2019 16:50:26 GMT

One nice thing about date strings in YYYY-MM-DD order is that they sort lexicographically in the same order as they do chronologically.

if chdt le '2019-01-10';

Re: how to filter dates based on character isodate

Kurt_Bremser — Tue, 10 Dec 2019 18:22:10 GMT

You can also use

if datepart(input(chdt,e8601dt.)) le input("2019-01-10",yymmdd10.);

Re: how to filter dates based on character isodate

noda6003 — Wed, 11 Dec 2019 11:34:40 GMT

what if the date is in char and is in "12 JAN 2019" format.

i tried where input(strip(chard),date9.) <= '12JAN2019'd; but it didnt work.

Any suggestions

Re: how to filter dates based on character isodate

Kurt_Bremser — Wed, 11 Dec 2019 11:43:34 GMT

You use the wrong function; strip() removes leading and trailing blanks, but you want to remove all blanks, so use compress():

data have;
input chard $11.;
datalines;
12 jan 2019
13 jan 2019
;

data want;
set have;
where input(compress(chard),date9.) <= '12JAN2019'd;
run;

Re: how to filter dates based on character isodate

novinosrin — Wed, 11 Dec 2019 12:40:21 GMT

Hi @noda6003 For embedded blanks, just read 2 more bytes of chars, so instead of date9. , use date11.

Example:

data w;
k=input("12 JAN 2019",date11.);
format k date9.;
run;

@noda6003 wrote:

what if the date is in char and is in "12 JAN 2019" format.

i tried where input(strip(chard),date9.) <= '12JAN2019'd; but it didnt work.

Any suggestions

Re: how to filter dates based on character isodate

ed_sas_member — Wed, 11 Dec 2019 12:45:38 GMT

Hi @noda6003

You can replace the strip() function by the compress() function to remove blanks.

Indeed, the strip() function can only remove leading and trailing blanks.

The compress() function remove all blanks.