topic Re: I need to resolve macro variable in single quotation in SAS Programming

I need to resolve macro variable in single quotation

thanikondharish — Mon, 09 Dec 2019 06:41:53 GMT

%let name=jhonson;

Data ex1;
Myname=%str('&name') ;
Run;

If I am running the above program the macro variable is not resolving within single quotation

Re: I need to resolve macro variable in single quotation

ScottBass — Mon, 09 Dec 2019 06:48:16 GMT

https://github.com/scottbass/SAS/blob/master/Macro/squote.sas

P.S.: Your particular example is poor - you'd just replace the single quotes with double quotes.

I'll run with your subject line and not your example.

Re: I need to resolve macro variable in single quotation

Kurt_Bremser — Mon, 09 Dec 2019 07:18:16 GMT

Why do you need single quotes? Please show us the (complete) desired end result.

Re: I need to resolve macro variable in single quotation

ed_sas_member — Mon, 09 Dec 2019 08:30:12 GMT

Hi @thanikondharish

Does that answer your question?

%let name=jhonson;

Data ex1;
Myname = compress(catx("","'","&name","'")) ;
Run;

Re: I need to resolve macro variable in single quotation

Jagadishkatam — Mon, 09 Dec 2019 08:33:53 GMT

you cannot resolve the &name or any macro variable with single quote, we need to use the double quotes to resolve the macro variables.

Re: I need to resolve macro variable in single quotation

s_lassen — Mon, 09 Dec 2019 09:56:14 GMT

Macro expressions in single quotes are not resolved. There are several ways to get you the result you want, one is to use double quotes as @ScottBass suggested:

Data ex1;
Myname="&name" ;
Run;

Another is to use the SYMGET function to get the value:

Data ex1;
Myname=symget('NAME');
Run;

If you absolutely need to get the macro value in single quotes, the easiest is probably to use the QUOTE function:

Data ex1;
Myname=%sysfunc(quote(&name,%str(%'))) ;
Run;

Re: I need to resolve macro variable in single quotation

FreelanceReinh — Mon, 09 Dec 2019 10:18:00 GMT

If you add outer double quotes, the macro variable reference will be resolved despite the inner single quotes:

data ex1;
Myname="'&name'";
run;

This assumes that you want the single quotes to be part of the string stored in the character variable.

Re: I need to resolve macro variable in single quotation

ScottBass — Mon, 09 Dec 2019 23:12:54 GMT

I just borrowed (stole?) Tom's original work for my macro.

See https://communities.sas.com/t5/SAS-Communities-Library/Not-All-Macro-Language-Elements-Are-Supported-by-the-Macro/ta-p/223904.

Re: I need to resolve macro variable in single quotation

PaigeMiller — Tue, 10 Dec 2019 02:10:33 GMT

At this point, the answers have been given to the question asked; but I think the real question that needs an answer is why do you want to resolve a macro variable in single quotes in the first place? This seems like a misunderstanding and could have been easily solved if only you told us what the real goal of the program and explained where you are and where you want to go, rather than you want to resolve a macro in single quotes.