topic Re: extract a substring from a string in SAS Programming

extract a substring from a string

QLi — Wed, 13 Jun 2012 20:26:50 GMT

All;

I have data as the following.

data have;

input string $40.;

datalines;

c 10 year fixed

n 30 year fixed

n 15 year fixed

sh nchfa fha 30 year

c 30 year fixed homepath

c 7 yr arm homepath

;

run;

I want to substring from a string to get the column like:

10 year

30 year

15 year

30 year

7 yr

Thanks

Re: extract a substring from a string

PGStats — Wed, 13 Jun 2012 20:58:55 GMT

The ideal candidate for PRX regular expressions :

data have;

input string $40.;

datalines;

c 10 year fixed

n 30 year fixed

n 15 year fixed

sh nchfa fha 30 year

c 30 year fixed homepath

c 7 yr arm homepath

;

data want(keep=y);

retain prxId;

set have;

if _n_ = 1 then prxId = prxparse("/\d+\s+y(ea)*r/i");

call prxsubstr(prxId, string, pos, len);

if pos>0 then do;

y = substr(string,pos, len);

output;

end;

run;

proc print; run;

PG Slightly improved the pattern

Re: extract a substring from a string

MikeZdeb — Wed, 13 Jun 2012 21:24:35 GMT

hi ... another idea ...

data want;

length y $10;

set have;

y = catx(' ',scan(substr(string,findc(string,,'d')),1),scan(substr(string,findc(string,,'d')),2));

run;

Re: extract a substring from a string

Linlin — Wed, 13 Jun 2012 23:06:13 GMT

how about:

data have;

input string $40.;

datalines;

c 10 year fixed

n 30 year fixed

n 15 year fixed

sh nchfa fha 30 year

c 30 year fixed homepath

c 7 yr arm homepath

;

data want(keep=new:);

length new_string $ 7;

set have;

new_string=catx(' ',compress(string,,'kd'),'year');

proc print;run;

Linlin

Re: extract a substring from a string

PGStats — Thu, 14 Jun 2012 00:34:22 GMT

Linlin, seems like QLi wants 'yr' on the last line.

Re: extract a substring from a string

Linlin — Thu, 14 Jun 2012 01:47:39 GMT

PG,

In that case, my code will not work.

Re: extract a substring from a string

Ksharp — Thu, 14 Jun 2012 02:21:31 GMT

Another PRX Function.

data  have;
input string $40.;
datalines;
c 10 year fixed
n 30 year fixed
n 15 year fixed
sh nchfa fha 30 year
c 30 year fixed homepath
c 7 yr arm homepath
;
run;
data want(drop=pid);
 set have;
 length year $ 20;
 retain pid;
 if _n_ eq 1 then pid=prxparse('/(\d+\s*(year|yr))/i');
 if prxmatch(pid,string) then year=prxposn(pid,1,string);
run;

Ksharp

Re: extract a substring from a string

PGStats — Thu, 14 Jun 2012 02:34:09 GMT

Very nice Ksharp!

Re: extract a substring from a string

QLi — Thu, 14 Jun 2012 13:06:16 GMT

It works great. Thanks, All