topic changing case of a specific word in a string. in SAS Programming

changing case of a specific word in a string.

Srikanth_J — Fri, 06 Dec 2019 14:26:05 GMT

data chk;
input name $9.;
name = tranwrd(name,"ae","AE");
cards;
aedef
ae
sae
dftaes ae
aerae
;
run;

I need the output as below:
aedef,
AE,
sae,
dftaes AE,
aerae

I need change the case of word ae to AE only if it exists as a word but not in between a word Thanks in advance, J.

Re: changing case of a specific word in a string.

novinosrin — Fri, 06 Dec 2019 14:39:10 GMT

HI @Srikanth_J What you need is FINDW as opposed to TRANWRD

if findw(name,'ae') then substr(name,findw(name,'ae'),2)='AE';

/*Using your example*/
data chk;
input name $9.;
name2=name;
if findw(name2,'ae') then substr(name2,findw(name2,'ae'),2)='AE';
cards;
aedef
ae
sae
dftaes ae
aerae
;
run;

Re: changing case of a specific word in a string.

Tom — Fri, 06 Dec 2019 14:40:21 GMT

You can use the INDEXW() function to find the locations where ae appears as a word.

data chk;
  input name $9.;
  do while(indexw(name,'ae'));
    substr(name,indexw(name,'ae'),2)='AE';
  end;
cards;
aedef
ae
sae
dftaes ae
aerae
;

Re: changing case of a specific word in a string.

ed_sas_member — Fri, 06 Dec 2019 14:48:50 GMT

Hi @Srikanth_J

You can try this also

data chk;
input name $9.;
name2 = strip(prxchange('s/(^|\s)(ae)(\s|$)/ AE /',-1,name));
cards;
aedef
ae
sae
dftaes ae
aerae
;
run;

Re: changing case of a specific word in a string.

Srikanth_J — Fri, 06 Dec 2019 14:51:49 GMT

Thank you @novinosrin.

Re: changing case of a specific word in a string.

Ksharp — Sat, 07 Dec 2019 11:50:39 GMT

data have;
input name $9.;
name2 = prxchange('s/\b(ae)\b/\U\1/',-1,name);
cards;
aedef
ae
sae
dftaes ae
aerae
;
run;