topic Removing completely the parentheses expression in SAS Programming

Removing completely the parentheses expression

farshidowrang — Mon, 02 Dec 2019 08:53:04 GMT

Hi guys,

I have special names which contain parentheses. I like to remove the whole parentheses expression.

What I have is this:

166/666-C-122 PP3(ZIAN)

199/999-H-888 ZZZ(PLING)

Z-12(AAAAAAA)

Z-2T (NILGON)

And what I need is this:

166/666-C-122 PP3

199/999-H-888 ZZZ

Z-12

Z-2T

Can you please help me with it?

Please note the space inside the names. Thank you!

Best regards

Farshid

Re: Removing completely the parentheses expression

ed_sas_member — Mon, 02 Dec 2019 08:58:17 GMT

Hi @farshidowrang

Assuming the word in parenthesis is at the end of the character expression, you can try this code:

data want;
	set have;
	var2 = trim(substr(var1, 1, index(var1,"(")-1));
run;

Re: Removing completely the parentheses expression

yabwon — Mon, 02 Dec 2019 09:16:05 GMT

Or maybe even something shorter:

data want;
	set have;
	var2 = scan(var1, 1, "(");
run;

All the best

Bart

Re: Removing completely the parentheses expression

PeterClemmensen — Mon, 02 Dec 2019 09:15:53 GMT

data have;
input string :$&100.;
datalines;
166/666-C-122 PP3(ZIAN)
199/999-H-888 ZZZ(PLING)
Z-12(AAAAAAA)
Z-2T (NILGON)
;

data want;
    set have;
    newstring=prxchange('s/\(.*\)//', -1, string);
run;

Result:

string                    newstring 
166/666-C-122 PP3(ZIAN)   166/666-C-122 PP3 
199/999-H-888 ZZZ(PLING)  199/999-H-888 ZZZ 
Z-12(AAAAAAA)             Z-12 
Z-2T (NILGON)             Z-2T

Re: Removing completely the parentheses expression

Ksharp — Mon, 02 Dec 2019 11:36:35 GMT

If you have such kind of data, you will get wrong result.

data have;
infile cards truncover;
input string $100.;
datalines;
166/666-C-(122) PP3(ZIAN)
199/999-H-(888) ZZZ(PLING)
Z-12(AAAAAAA)
Z-2T (NILGON)XXXX
;

data want;
    set have;
    newstring=prxchange('s/\(.*?\)//', -1, string);
run;