topic Re: How to generate a duplicate code which looks similar? in SAS Programming

How to generate a duplicate code which looks similar?

Dominus — Thu, 28 Nov 2019 07:35:51 GMT

I want to generate a series SAS code like:

data want;
    length name label $ 200.;
    name  = "country='Country_A'";
    label = "Country_A";
    output;

    name  = "country='Country_B'";
    label = "Country_B";
    output;

    name  = "country='Country_C'";
    label = "Country_C";
    output;

    *(...etc. so many countries, ie: Country_A to Country_Z);
run;

Is there a simple way in SAS to get there that I can generate such code just by typing less words.

Array?Macro? or any other methods?

Thanks in advance.

Best regards.

Re: How to generate a duplicate code which looks similar?

PeterClemmensen — Thu, 28 Nov 2019 07:37:12 GMT

Why do you want to do this? Seems to be part of a bigger problem?

Re: How to generate a duplicate code which looks similar?

Dominus — Thu, 28 Nov 2019 07:43:34 GMT

Cause this is a necessary data step to create a conditional judgement dataset for other calculation.

Re: How to generate a duplicate code which looks similar?

Dominus — Thu, 28 Nov 2019 07:45:20 GMT

Or a simple way to create the want dataset

Re: How to generate a duplicate code which looks similar?

andreas_lds — Thu, 28 Nov 2019 07:45:46 GMT

This is indeed a strange requirement, but easy to solve:

data want;
    length 
      name label $ 200
      i 8
   ;
   drop i;

   do i = rank('A') to rank('Z');
      name  = cats("country='Country_", byte(i), "'");
      label = cats("Country_", byte(i));
      output;
   end;
run;

Re: How to generate a duplicate code which looks similar?

Dominus — Thu, 28 Nov 2019 07:52:22 GMT

Thank you for the answer, I'll try it. Actually, the country names are not a sequence.

Re: How to generate a duplicate code which looks similar?

PeterClemmensen — Thu, 28 Nov 2019 07:58:42 GMT

Then what defines your country names? Do you have them in a separate data set or?

Re: How to generate a duplicate code which looks similar?

Dominus — Thu, 28 Nov 2019 08:00:55 GMT

Not a separate data set. Maybe I can put them in a list or a data set.

Re: How to generate a duplicate code which looks similar?

Dominus — Thu, 28 Nov 2019 08:34:08 GMT

Thanks you. I got what I want.

data want;
    length name label $ 200 i 8;

    array country[6] $100 ('Country A' 'Country B' 'Country C'
                           'Country D' 'Country E' 'Country F');

    do i = 1 to 6;
        name  = cats("country='", country[i], "'");
        label = cats(country[i]);
        output;
    end;

    drop i country: ;
run;

Re: How to generate a duplicate code which looks similar?

gamotte — Thu, 28 Nov 2019 13:28:33 GMT

@Dominus,

Note that you can avoid creating actual columns in your dataset by declaring your array as temporary.

    array country[6] $100 _TEMPORARY_ ('Country A' 'Country B' 'Country C'
                           'Country D' 'Country E' 'Country F')

Re: How to generate a duplicate code which looks similar?

Dominus — Mon, 02 Dec 2019 05:42:05 GMT

Thank you for the useful tips.