topic Re: How can I create a dataset with all unique values of over 100 variables? in SAS Programming

How can I create a dataset with all unique values of over 100 variables?

Linlin — Tue, 21 May 2013 18:09:26 GMT

Dear All,

How should I get what I want?

Thank you very much for your input!

data have;
input (a b c) ($);
cards;
dd ee ff
ff hh gg
ss dd hh
;

observations in the dataset I want:

dd
ee
ff
hh
gg
ss

Re: How can I create a dataset with all unique values of over 100 variables?

Tom — Tue, 21 May 2013 18:19:35 GMT

Rotate the data into a single column and let proc sort/FREQ/SQL find the distinct values.

data middle / view=middle;

set have;

array _all a b c;

do over _all; value = _all; output; end;

run;

proc freq data=middle ;

tables value / out=want missing;

run;

Re: How can I create a dataset with all unique values of over 100 variables?

Haikuo — Tue, 21 May 2013 18:26:15 GMT

Or Hash():

data have;

input (a b c) ($);

cards;

dd ee ff

ff hh gg

ss dd hh

;

data _null_;

if _n_=1 then do;

declare hash h();

h.definekey('newvar');

h.definedata('newvar');

h.definedone();

end;

set have end=last;

array t _character_;

length newvar $ 8;

call missing(newvar);

do over t;

rc=h.replace(key:t, data:t);

end;

if last then rc=h.output(dataset:'want');

run;

Haikuo

Re: How can I create a dataset with all unique values of over 100 variables?

PGStats — Tue, 21 May 2013 18:30:23 GMT

Hi Linlin,

Use a variable list a--c to refer to your 100 variables (assuming they are listed consecutively) :

data have;
input (a b c) ($);
cards;
dd ee ff
ff hh gg
ss dd hh
;
data list;
set have;
array _a{*} a--c;
do i = 1 to dim(_a);
     value = _a{i};
     output;
     end;
run;

proc sql;
create table uniqueValues as
select unique value from list;
select * from uniqueValues;
quit;

Re: How can I create a dataset with all unique values of over 100 variables?

Linlin — Tue, 21 May 2013 18:45:26 GMT

Hi Tom, Haikuo, and PG:

Thank you very much for your help!!! - Linlin

Re: How can I create a dataset with all unique values of over 100 variables?

sandyming — Tue, 02 Jul 2013 17:55:27 GMT

Wow, three excellent ways to solve the problem!