topic Re: macro variable during data step in SAS Programming

macro variable during data step

Brian3 — Thu, 14 Nov 2019 16:05:08 GMT

Hi,

the situation I have is a list of macro variables like follows;

var_2030

var_2031

var_2032

etc.

During the data step, which involves a loop, I need to use more than one:

data test;

x=2;

do i=1 to 3;

%let t=2030+i;

If x<&&var_&t then put 'success';

%end;

run;

Unfortunately, &&var_&t resolves as (var_2030) + i instead of (var_(2030+i)).

I've tried using %let t=%sysevalf(2030+i) but it then complains that there is a character variable instead of numeric. I also understand this may be related to macro values being evaluated before data steps are executed, so is this possible?

Thanks very much.

Re: macro variable during data step

Reeza — Thu, 14 Nov 2019 16:07:22 GMT

From what you've posted here you should be using an array not a macro.

That being macro variables are not resolved in the same step they're created. THere are many ways to get around this, but given that you don't need macros my first suggestion is to switch to arrays instead.

Here's a tutorial on using Arrays in SAS
https://stats.idre.ucla.edu/sas/seminars/sas-arrays/

@Brian3 wrote:

Hi,

the situation I have is a list of macro variables like follows;

var_2030

var_2031

var_2032

etc.

During the data step, which involves a loop, I need to use more than one:

data test;

x=2;

do i=1 to 3;

%let t=2030+i;

If x<&&var_&t then put 'success';

%end;

run;

Unfortunately, &&var_&t resolves as (var_2030) + i instead of (var_(2030+i)).

I've tried using %let t=%sysevalf(2030+i) but it then complains that there is a character variable instead of numeric. I also understand this may be related to macro values being evaluated before data steps are executed, so is this possible?

Thanks very much.

Re: macro variable during data step

Kurt_Bremser — Thu, 14 Nov 2019 16:14:44 GMT

Your code can't run anyway because of syntax errors. You have a do without an end, and a % end without a %do.

And if it was just a typo and it is a %do, that is not possible in open code, and I see no macro definition around your code.

From what I can guess, I take it that you have a bad dataset design (wide instead of long/tall), forcing you to write complicated code for something that is most probably an extremely simple task in SAS, needing no macro code at all.

So you first need to make your data intelligent (Maxim 33) by transposing; for further help, please provide example data in usable form (data step with datalines), and what you want to get as a result out of it.

Re: macro variable during data step

Brian3 — Thu, 14 Nov 2019 16:22:03 GMT

Thanks, for the task I'm doing I have to leave them as macro variables. Is there a way to do that?

Re: macro variable during data step

Brian3 — Thu, 14 Nov 2019 16:23:07 GMT

There should not be a %. It should be end.

Re: macro variable during data step

Kurt_Bremser — Thu, 14 Nov 2019 16:30:09 GMT

@Brian3 wrote:
Thanks, for the task I'm doing I have to leave them as macro variables. Is there a way to do that?

No. Macro variables are resolved during data step compilation, so there's no way you can dynamically address them depending on values present while the data step executes. This is a very typical beginner's misconception when they do not yet understand the nature of the macro language as a code generator, not a data processing tool.

Please give us data and the expected result.

Re: macro variable during data step

Tom — Thu, 14 Nov 2019 16:31:21 GMT

Before trying to use macro code to generate SAS code first figure out want SAS code you want to run.

It sounds like you want to do the following.

data want;
  set have ;
  success = .Z < x < max(of VAR_2030-VAR_2032);
run;

Now if your variable names really are in that form of a common base and numeric suffix and you want all of them from some minimum suffix to some maximum suffix then you just need to two macro variables to how those two numbers to generate the code.

%let min=2030;
%let max=2032;
data want;
  set have ;
  success = .Z < x < max(of VAR_&min.-VAR_&max.);
run;

Re: macro variable during data step

Reeza — Thu, 14 Nov 2019 16:45:25 GMT

@Brian3 wrote:
Thanks, for the task I'm doing I have to leave them as macro variables. Is there a way to do that?

Then you need to provide a more representative sample of your issue.

Re: macro variable during data step

Brian3 — Thu, 14 Nov 2019 16:45:36 GMT

it is more the principle I am trying to do rather than specific data. Basically how to work with macro variables which can change value during a data step. Surely SAS has some ability to let me do that. Maybe I can use arrays, but not sure how it works with macro variables.

Re: macro variable during data step

Reeza — Thu, 14 Nov 2019 16:51:27 GMT

What makes you think you need macro variables at all.

Re: macro variable during data step

Brian3 — Thu, 14 Nov 2019 16:53:04 GMT

its just because they are already macro variables. If there's a quick way to convert them to data values, that would be ok.

Re: macro variable during data step

Reeza — Thu, 14 Nov 2019 16:59:37 GMT

Use the macro variables to define your array definition then, which is dynamic and then you can use the array without any issues. First develop working code - non macro. If you show us what that looks like we can help you convert it to a macro. Right now we have an xy problem.

Re: macro variable during data step

Brian3 — Thu, 14 Nov 2019 17:06:22 GMT

Hmm I've never used arrays before. Ok so

data test;

x=2;

%let var1=4;

%let var2=1;

%let var3=2;

array &var[3];

do i=1 to 2;

If x>&var[i] then put 'success';

end;

run;

Re: macro variable during data step

Tom — Thu, 14 Nov 2019 17:18:24 GMT

No need for an array there as you are just dealing with numeric constants and not variables.

%let var1=4;
%let var2=1;
%let var3=2;

data test;
  x=2;
  if x > min(&var1, &var2, &var3) then put 'success';
run;

Much easier if you just put the list of values into a single macro variable instead.

%let list=4, 1, 2;

data test;
  x=2;
  if x > min(&list) then put 'success';
run;

Note: Make sure to move your %LET statements BEFORE the DATA statement. That is when they will execute so placing them there in the code will be less confusing to you.

Re: macro variable during data step

Kurt_Bremser — Thu, 14 Nov 2019 17:20:18 GMT

@Brian3 wrote:

it is more the principle I am trying to do rather than specific data. Basically how to work with macro variables which can change value during a data step. Surely SAS has some ability to let me do that. Maybe I can use arrays, but not sure how it works with macro variables.

You are still on the completely wrong path here. The macro language is a code generator, helping you in automatically writing dynamic code, but it is the wrong tool for dealing with data.

So if you want to start learning the use of the macro language, you need to start with code that needs to be made dynamic to respond to certain outside conditions, not with data issues. For these you use arrays, retained variables, lag functions, look-ahead reading, hash objects, and so on.

Re: macro variable during data step

Brian3 — Thu, 14 Nov 2019 17:27:06 GMT

I've tried using arrays above.

Re: macro variable during data step

Tom — Thu, 14 Nov 2019 17:33:50 GMT

Here is an ARRAY example.

First start with some data that has a series of similar variables.

data have ;
  input x y1-y5 ;
cards;
2 1 1 0 0 0 
1 1 2 3 4 5
;

Now you can use an ARRAY to reference the five "y" variables.

Perhaps like this:

data want;
  set have ;
  array y y1-y5;
  success = x < min(of y[*]);
run;

Or by using an index into the array.

data _null_;
  set have;
  array y y1-y5 ;
  do index=1 to dim(y);
     if x < y[index] then put x= 'is less than ' y[index]=;
  end;
run;

Re: macro variable during data step

Brian3 — Thu, 14 Nov 2019 17:33:59 GMT

ok sas is useless I'll just use data values and an array.

Re: macro variable during data step

Tom — Thu, 14 Nov 2019 17:37:38 GMT

@Brian3 wrote:

ok sas is useless I'll just use data values and an array.

Exactly. Start by learning how to use SAS. Once you understand how to do things in SAS you can then figure out how to use macro language to generate that code. You cannot build a house without a solid foundation.

Re: macro variable during data step

Kurt_Bremser — Thu, 14 Nov 2019 17:39:53 GMT

If you want to create an array out of macro variables, see this:

%let var1=4;
%let var2=1;
%let var3=2;

data test;
x = 2;
array var[3] (&var1, &var2, &var3);
do i = 1 to 3;
  If x > var[i] then put i ', success';
end;
run;

the %let statements are now where they belong to reflect the point in time where they are resolved
the macro variables are used at a static point resolved during data step compilation
the array is defined correctly (without the erroneous macro variable reference)