topic how to get a variable label in to a macro variable in SAS Programming

how to get a variable label in to a macro variable

knveraraju91 — Fri, 08 Nov 2019 17:13:29 GMT

Dear,

I need help on how to get a variable label name in to macro variable.

data one;
input age Ageu $;
datalines;
12 Y
;

Suppose the age variable label is 'age in years'. I need to create a macro variable with label value.

%let want=;

output needed;

want='age in years'.

Please suggest. Thank you

Re: how to get a variable label in to a macro variable

ballardw — Fri, 08 Nov 2019 17:45:15 GMT

So where are we suppose to "get" the variable label from? The data set you create has no label assigned so there isn't any place to get the label from.

If you SET from a data set that has an assigned label you can use the vlabel function in a data step.

data example;
   x=3;
   label x ='Some label';
run;

data _null_;
   set example (obs=1);
   labeltext= vlabel(x);
   call symputx('xlabel',labeltext);
run;

%put label for x is: &xlabel.;

Or extract the value from sashelp.vcolumn view or the Dictionary.columns table in Proc SQL using :INTO

Re: how to get a variable label in to a macro variable

r_behata — Fri, 08 Nov 2019 17:47:42 GMT

Try the VARLABEL Function

https://documentation.sas.com/?docsetId=lefunctionsref&docsetTarget=n15lqt6a2pdg1in1w295ql8wel1a.htm&docsetVersion=1.0&locale=en

Re: how to get a variable label in to a macro variable

chaatak — Fri, 08 Nov 2019 17:56:46 GMT

data one;
 input age Ageu $;
 attrib age label="Age in Years";
 datalines;
12 Y
;

proc print data = one label;

data _NULL_;
 set one;
 file print;
 length lab $50.;
 call label (age, lab);
 call symput ('want', lab);
 put lab = ;
run;

%put &want;

Re: how to get a variable label in to a macro variable

mkeintz — Fri, 08 Nov 2019 19:00:37 GMT

@chaatak :

Good advice, but I would tweak your program just a little. If the only goal is to retrieve and report the label of a variable, then there is no need to read every observation (or any observation at all) from data set ONE. After all, if ONE had one million observations, there is no need to issue the CALL label and CALL symput 1mm times. Yes, in your sample dataset, this not a problem.

But as a defensive measure you could just change the "set one:" statement to:

set one (obs=1);

I did say you don't even have to read one observation, because another option is:

if 0 then set one;

For this task, it won't be any more efficient than the "(obs=1)" approach, but it's a good device for reminder yourself that this data step is about meta-data, not data.