topic Re: How to check words (from one column) in text (from another column) in SAS Programming

How to check words (from one column) in text (from another column)

krishmar1 — Thu, 12 Sep 2013 21:12:47 GMT

Hi,

I have a dataset A with a column named Location and a dataset B with a column named Keyword.

Location has rows like:

Texas
Florida
Arizona

which stores any single word.

Keyword stores rows with text, for example: I live in Florida.

I would like to list all the rows in Keyword if any of the words in location exists in Keyword.

So keyword in the above example would be listed but not if the row of Keyword is "I am a vagabond"

How do I code this in SAS --- using a data step or Proc SQL or any other proc?

Please help!

Thanks,

Re: How to check words (from one column) in text (from another column)

Scott_Mitchell — Fri, 13 Sep 2013 01:35:24 GMT

You could use SQL.

DATA T1;

INPUT LOCATION $;

DATALINES;

TEXAS

FLORIDA

ARIZONA

;

RUN;

DATA T2;

LENGTH KEYWORD $40;

INFILE DATALINES DLM=',';

INPUT KEYWORD $;

DATALINES;

I AM A VAGABOND

I LOVE TEXAS

I HATE ARIZONA

;

RUN;

PROC SQL;

CREATE TABLE WANT AS

SELECT *

FROM T1,T2

WHERE FIND(T2.KEYWORD,T1.LOCATION) > 0

;

RUN;

Re: How to check words (from one column) in text (from another column)

krishmar1 — Fri, 13 Sep 2013 02:53:39 GMT

Thank you, Scott.

Do you know how I can have an indicator variable (binary) for each row where FIND(T2.KEYWORD,T1.LOCATION) > 0 so that I can differentiate between the rows with the location and the rows without

Regards,

Re: How to check words (from one column) in text (from another column)

PGStats — Fri, 13 Sep 2013 03:16:53 GMT

Change the last step to:

PROC SQL;

CREATE TABLE WANT AS

SELECT

T2.keyword,

T1.location,

T1.location IS NOT MISSING as indicator

FROM T2 LEFT JOIN T1

ON FIND(T2.KEYWORD ,T1.LOCATION) > 0;

QUIT;

Re: How to check words (from one column) in text (from another column)

Scott_Mitchell — Fri, 13 Sep 2013 03:18:29 GMT

How is this?

PROC SQL;

CREATE TABLE WANT AS

SELECT A.KEYWORD, B.INDIC

FROM T2 A

LEFT JOIN

(SELECT KEYWORD, 1 AS INDIC

FROM T1,T2

WHERE FIND(T2.KEYWORD,T1.LOCATION) > 0) B

ON A.KEYWORD = B.KEYWORD

;

RUN;

Re: How to check words (from one column) in text (from another column)

krishmar1 — Fri, 13 Sep 2013 16:47:11 GMT

Thank you, Scott and PGStats.