topic Re: proc sgplot show lines splitting graph into 4 sections? in SAS Programming

proc sgplot show lines splitting graph into 4 sections?

serrld113 — Thu, 31 Oct 2019 18:27:31 GMT

Hi there, Is there a way to separate my graph into 4 quadrants like in the picture? I'd want the lines to go through the 50 mark on both axis.

Thank you

Re: proc sgplot show lines splitting graph into 4 sections?

PeterClemmensen — Thu, 31 Oct 2019 18:49:44 GMT

See if this gets you started. Feel free to ask

data have;
   do x=1 to 100;
      y=rand('integer', 0, 100);
      output;
   end;
run;

data plot;
   set have;
        if x <= 50 & y <= 50 then group=1;
   else if x >  50 & y <= 50 then group=2;
   else if x <= 50 & y >  50 then group=3;
   else if x >  50 & y >  50 then group=4;
run;

proc sgplot data=plot noautolegend;
   scatter x=x y=y / group=group markerattrs=(symbol=circlefilled size=10) colorresponse=group colormodel=(blue gold red green);
   refline 50 / axis=x lineattrs=(thickness=2 color=black);
   refline 50 / axis=y lineattrs=(thickness=2 color=black);
run;

Result:

Re: proc sgplot show lines splitting graph into 4 sections?

serrld113 — Thu, 31 Oct 2019 18:51:17 GMT

thank you this is perfect!