topic Re: Feeding the top 25 diagnoses into the next program in SAS Programming

Feeding the top 25 diagnoses into the next program

hein68 — Mon, 28 Oct 2019 18:02:01 GMT

I have code like this (see below) where I get the top 25 diagnoses:

proc freq data=&dataems order=freq;
tables diag1CCS/noprint out=counts;
run;

data state;
set counts (obs=25);
drop percent;
run;

Then I want to write another program to go back to my original data (&dataems) and keep only the records with the top 25 diag1ccs categories. How could I do that without having to copy and paste the top 25 diag1ccs categories into another data step? I want a more automated process, because I will end up having to do this over 100 times.

Thanks for your help.

Re: Feeding the top 25 diagnoses into the next program

GPatel — Mon, 28 Oct 2019 18:11:55 GMT

Please refer to following two papers :

https://support.sas.com/resources/papers/proceedings/proceedings/sugi31/249-31.pdf

https://support.sas.com/resources/papers/proceedings/proceedings/sugi30/001-30.pdf

Re: Feeding the top 25 diagnoses into the next program

PaigeMiller — Mon, 28 Oct 2019 18:40:04 GMT

@hein68 wrote:

I have code like this (see below) where I get the top 25 diagnoses:

proc freq data=&dataems order=freq;
tables diag1CCS/noprint out=counts;
run;

data state;
set counts (obs=25);
drop percent;
run;

Then I want to write another program to go back to my original data (&dataems) and keep only the records with the top 25 diag1ccs categories. How could I do that without having to copy and paste the top 25 diag1ccs categories into another data step? I want a more automated process, because I will end up having to do this over 100 times.

Thanks for your help.

How about PROC SQL

proc sql;
    create table new as select * from &dataems 
        where diag1ccs in (Select distinct diag1ccs from state);
quit;

Re: Feeding the top 25 diagnoses into the next program

Reeza — Mon, 28 Oct 2019 18:56:16 GMT

Is diagnosis a single file or do you need to search all 25 (usual number) of diagnosis fields?

@hein68 wrote:

I have code like this (see below) where I get the top 25 diagnoses:

proc freq data=&dataems order=freq;
tables diag1CCS/noprint out=counts;
run;

data state;
set counts (obs=25);
drop percent;
run;

Then I want to write another program to go back to my original data (&dataems) and keep only the records with the top 25 diag1ccs categories. How could I do that without having to copy and paste the top 25 diag1ccs categories into another data step? I want a more automated process, because I will end up having to do this over 100 times.

Thanks for your help.

Re: Feeding the top 25 diagnoses into the next program

hein68 — Mon, 28 Oct 2019 19:12:56 GMT

This is great! Thanks!!

Re: Feeding the top 25 diagnoses into the next program

PGStats — Mon, 28 Oct 2019 19:17:58 GMT

Take advantage of BY processing, instead of macro processing. It's more efficient and easier to code. Here is an example calculating the median weight of students from the top three age groups, for each sex :

proc sort data=sashelp.class out=class; 
by sex age; 
run;

proc freq data=class order=freq;
by sex;
tables age/noprint out=counts;
run;
 
data keep;
do i = 1 by 1 until(last.sex);
   set counts; by sex;
   if i <= 3 then output;
   end;
drop i percent;
run;

data select;
merge class keep(in=ok);
by sex age;
if ok;
run;

proc means data=select noprint;
by sex;
var weight;
output out=medians median=med;
run;