topic Re: Macro variable with value OR in %IF Condition in SAS Programming

Macro variable with value OR in %IF Condition

Jakkas — Sat, 19 Jan 2013 17:33:20 GMT

Hello,

I have a small macro which conditionally executes code bases on state abbreviation. I want to execute some code for Oregon (State abbreviation OR). The code I am having trouble with is the following:

%MACRO Test(ST);
     %IF &ST. = OR %THEN %DO;
           %PUT State is Oregon.;
     %END;
     %ELSE %DO;
           %PUT State is not Oregon.;
     %END;
%MEND;

%Test(OR);

I think the issue is because OR is a keyword. The macro works fine for PA, or IN and so on but not for OR. Is there a quoting function or something I can use to overcome this issue? Thank you.

Re: Macro variable with value OR in %IF Condition

Linlin — Sat, 19 Jan 2013 17:52:48 GMT

try:

%MACRO Test(ST);

%IF &ST. = "OR" %THEN %DO;

%PUT State is Oregon.;

%END;

%ELSE %DO;

%PUT State is not Oregon.;

%END;

%MEND;

%Test("PA");

Re: Macro variable with value OR in %IF Condition

Astounding — Sat, 19 Jan 2013 22:33:24 GMT

A small tweak to the suggested solution: double quotes on both sides.

%if "&st." = "OR" %then %do;

Macro quoting functions could be used, but at least for this simple test the double quotes will work fine.

Re: Macro variable with value OR in %IF Condition

Peter_C — Sat, 19 Jan 2013 23:36:27 GMT

macro quoting to protect against finding a variable resolves to what looks like logic is straightforward in this case.

rather that quotes use the function %str()

%if %str(&st) EQ %str(OR) %then %do;

/* whatever you need to do for OR */

%end;

Re: Macro variable with value OR in %IF Condition

data_null__ — Sun, 20 Jan 2013 15:04:17 GMT

I was thinking that %STR(&ST) would not be the right function but it does work when the value of ST=OR. Guess I need to RTFM.

I think using and execution time function is safer.

19            %if %superq(st) eq %str(OR) %then %do; 
20               %PUT ST=&st;
21               %end; 
22            %else %put not or;
23            %if %str(&st) eq %str(OR) %then %do; 
24               %PUT ST=&st;
25               %end; 
26            %else %put not or;
27            %mend; 
28         
29         %ck(st=|)
not or
ERROR: A character operand was found in the %EVAL function or %IF condition where a numeric operand is required. The condition was: 
       &st eq OR 
ERROR: The macro CK will stop executing.

Re: Macro variable with value OR in %IF Condition

Peter_C — Sun, 20 Jan 2013 18:43:02 GMT

I can't be giving data_null_; explanations I'm used to those flowing in the other direction!

here %str() is suitable because of the limited range of values that &ST might take - all state abbreviations. the time when extra protection is necessary occurs when the macro variable might contain special symbols not "protected" by %str(). These special symbols % and & would be well protected by%superq() but might need no more than %nrstr() - depending on the timing required for resolving values.

IN general defensive programming recommends %superq() as data_null; suggested here.

%Str() is adequate on this occasion because we know what range of values &ST will take.

Re: Macro variable with value OR in %IF Condition

Florent — Mon, 21 Jan 2013 12:44:21 GMT

The following code works:

%MACRO Test(ST);

%IF "&ST" = "OR" %THEN %DO;

%PUT State is Oregon.;

%END;

%ELSE %DO;

%PUT State is not Oregon.;

%END;

%MEND;

%Test(OR);